VBScript

Create Email with Non-Standard Binary Body

Creates an email where the only body is a binary WAV file. The technique used in the example could be applied to other binary files, such as PDF, MS-WORD docs, Excel docs, etc. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set mime = CreateObject("Chilkat.Mime")

success = mime.SetBodyFromFile("VoiceMessage.wav")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

' The MIME has this header:
' Content-Disposition: attachment;
' 	 filename="VoiceMessage.wav"
' Content-Transfer-Encoding: base64
' Content-Type: audio/x-wav;
' 	name="VoiceMessage.wav"

' We don't want the content-disposition to be an
' attachment -- otherwise the email object will self-correct
' and put it in a multipart/mixed format...
mime.Disposition = ""
mime.Filename = ""

strMime = mime.GetMime()
outFile.WriteLine(strMime)

' Now load it into an email object:
set email = CreateObject("Chilkat.Email")
success = email.SetFromMimeText(strMime)
If (success = 0) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' Add subject, TO, FROM, etc.
email.Subject = "This is a test"
email.From = "support@chilkatsoft.com"
success = email.AddTo("Matt","matt@chilkatsoft.com")

' Your email is ready to send.
' (but for this example, we'll simply save it to a file...)
success = email.SaveEml("email.eml")
If (success = 0) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("OK!")

outFile.Close