(VBScript) Multipart/Alternative Email

It is very common for email to contain both plain-text and HTML alternative bodies. When a mail client such as Outlook, Eudora, or Thunderbird receives such an email, it will display one of the alternatives. The default is usually to display the HTML alternative. (In addition, the latest versions of email clients default to blocking HTML images from displaying for anti-SPAM reasons.) Emails with both plain-text and HTML alternative bodies are structured (in MIME) as multipart/alternative. The Chilkat Email component handles the MIME formatting of an email for you, so you don't have to worry about the details of the MIME composition. This example shows how to create an email with both plain-text and HTML alternative bodies.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

' First, add the typical header fields...
email.Subject = "This email has alternative bodies"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")
email.From = "Matt <matt@chilkatsoft.com>"

' Setting the Body property makes a text/plain email:
email.Body = "This is the plain-text body"

' At this point, our email is a simple plain/text email
' with no alternatives:
success = email.SaveEml("plainText.eml")

' Now add an HTML alternative:
success = email.AddHtmlAlternativeBody("<html><body>This is the <b>HTML body</b></body></html>")
success = email.SaveEml("plainTextAndHtml.eml")

' To create an HTML-only email, do this:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email2 = CreateObject("Chilkat.Email")

' First, add the typical header fields...
email2.Subject = "This email has alternative bodies"
success = email2.AddTo("Chilkat Support","support@chilkatsoft.com")
email2.From = "Matt <matt@chilkatsoft.com>"

email2.SetHtmlBody "<html><body>This is the <b>HTML body</b></body></html>"
success = email2.SaveEml("htmlOnly.eml")

' Add a plain-text alternative:
success = email2.AddPlainTextAlternativeBody("This is the plain-text body")
success = email2.SaveEml("plainTextAndHtml2.eml")

' To replace the plain-text alternative, just set the Body property:
email2.Body = "This is the new plain-text body"

' To replace the HTML alternative, call SetHtmlBody:
email2.SetHtmlBody "<html><body>This is the new HTML body...</body></html>"

success = email2.SaveEml("plainTextAndHtml2a.eml")

' To determine if an email has a particular alternative body,
' call HasPlainTextBody or HasHtmlBody:
If (email2.HasPlainTextBody() = 1) Then
    outFile.WriteLine("Has plain-text body!")
End If

If (email2.HasHtmlBody() = 1) Then
    outFile.WriteLine("Has HTML body!")
End If


outFile.Close