(VBScript) Create Complex Email

This is an example showing how to create an email that has file attachments, contains both plain-text and HTML alternative bodies, and has embedded images within the HTML. The email is saved to a .eml file, which is a text file and can be viewed in any text editor. EML is nothing more than the MIME source of an email. In this example, you'll see that the MIME is structured in three layers of multipart content types. The outermost layer is multipart/mixed. This is typically where you'll find file attachments and attached messages. Underneath the multipart/mixed is a multipart/related envelope. Within this you'll find the "related" items -- which are the items belonging to the HTML body (images and style sheets). Underneath the multipart/related you'll find the multipart/alternative, and this contains the text/plain and text/html alternative bodies.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

' Adding attachments, HTML/plain-text bodies, etc can be done
' in any order:

' Add an attachment
contentType = email.AddFileAttachment("hamlet.zip")
If (email.LastMethodSuccess <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' Add some headers:
email.Subject = "This is a complex email"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")
email.From = "Matt <matt@chilkatsoft.com>"

' Add a plain-text body:
success = email.AddPlainTextAlternativeBody("This is the plain-text body")

' Add an image that will be embedded in the HTML body.
contentIdDude = email.AddRelatedFile("dude.gif")
If (email.LastMethodSuccess <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' Update the CONTENT_ID_DUDE to the actual content ID when sending the email.
success = email.SetReplacePattern("CONTENT_ID_DUDE",contentIdDude)

' Add an HTML body:

html = "<html><body><b>This is the HTML body</b><br><img src=""cid:CONTENT_ID_DUDE""></body></html>"

success = email.AddHtmlAlternativeBody(html)

' Save the email as a .eml

success = email.SaveEml("complex.eml")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
Else
    outFile.WriteLine("Created email!")
End If


outFile.Close