VBScript

Set the Email Date Header to the Current System Date/Time

Demonstrates how to set the Date header field of an email to the computer's current date/time. Note: When an email object is instantiated, the Date header field is automatically added and initialized to the current system date/time. The need to explicitly set the Date header could arise when loading an email from a .eml. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set email = CreateObject("Chilkat.Email")

' At this point, a new email object has been instantiated, and it
' already has a Date header field containing the current date/time.
outFile.WriteLine("Date: " & email.EmailDateStr)

' We can also get the Date header like this:
outFile.WriteLine("Date: " & email.GetHeaderField("Date"))

' Load a .eml into the email object:
success = email.LoadEml("myEmlFiles/someEmail.eml")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' Show the Date that was in the .eml
outFile.WriteLine("Date: " & email.EmailDateStr)

' Now the Date header contains whatever was in the .eml
' Let's update it to the current system date/time..

set dateTime = CreateObject("Chilkat.CkDateTime")

success = dateTime.SetFromCurrentSystemTime()

success = email.SetDt(dateTime)
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' Now show that the Date is the current system time:
outFile.WriteLine("Date: " & email.EmailDateStr)
outFile.WriteLine("Date: " & email.GetHeaderField("Date"))

outFile.Close