(VBScript) UN/EDIFACT Syntax Level A Encoding/Decoding

Demonstrates the new "eda" encoding that can be used throughout Chilkat starting in v9.5.0.65.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: Requires Chilkat v9.5.0.65 or greater.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
success = sb.Append("The 5 men of 223rd St")
outFile.WriteLine(sb.GetAsString())

' Encode the utf-8 byte representation of the string in the 
' UN/EDIFACT syntax level A character set.
success = sb.Encode("eda","utf-8")
outFile.WriteLine(sb.GetAsString())

' EDA Output should be: BTME027FCF6CFARFI94JT6.)F(14KJ2U

' Decode back to the original string.
success = sb.Decode("eda","utf-8")
outFile.WriteLine(sb.GetAsString())
outFile.WriteLine("----")

' The following requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The "eda" encoding can be used anywhere within Chilkat.
' For example, with the Crypt2 API
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256
crypt.EncodingMode = "eda"

ivHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV ivHex,"hex"
keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

encStr = crypt.EncryptStringENC("The quick brown fox jumps over the lazy dog.")
' The output is UN/EDIFACT syntax level A 
outFile.WriteLine(encStr)

' Now decrypt:
decStr = crypt.DecryptStringENC(encStr)
outFile.WriteLine(decStr)

outFile.Close