VBScript

Ed25519 Sign and Verify

See more Ed25519 Examples

Demonstrates how to create an Ed25519 signature, and then to verify it.

Note: This example requires Chilkat v9.5.0.83 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

privKeyHex = "1498b5467a63dffa2dc9d9e069caf075d16fc33fdd4c3b01bfadae6433767d93"
pubKeyHex = "b7a3c12dc0c8c748ab07525b701122b88bd78f600c76342d27f25e5f92444cde"

set privKey = CreateObject("Chilkat.PrivateKey")
' This example shows only one way of loading an Ed25519 private key.
' Chilkat can load other formats (JWK, PEM, ASN.1 DER, etc.)  
' You may do so by calling LoadAnyFormat or LoadAnyFormatFile.
success = privKey.LoadEd25519(privKeyHex,pubKeyHex)
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' The data to be signed...
set bd = CreateObject("Chilkat.BinData")
success = bd.AppendString("Message for Ed25519 signing","utf-8")

set eddsa = CreateObject("Chilkat.EdDSA")
hexSig = eddsa.SignBdENC(bd,"hexlower",privKey)

outFile.WriteLine("signature = " & hexSig)

' The expected output is: 6dd355667fae4eb43c6e0ab92e870edb2de0a88cae12dbd8591507f584fe4912babff497f1b8edf9567d2483d54ddc6459bea7855281b7a246a609e3001a4e08

' Verify the signature..
set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadEd25519(pubKeyHex)
If (success = 0) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

bVerified = eddsa.VerifyBdENC(bd,hexSig,"hexlower",pubKey)
If (bVerified = 0) Then
    outFile.WriteLine(eddsa.LastErrorText)
    outFile.WriteLine("Failed to verify the signature.")
    WScript.Quit
End If

outFile.WriteLine("The Ed25519 signature is verified!")

outFile.Close