VBScript

ECDSA Sign Data and Get Raw R and S Values

See more ECC Examples

Demonstrates getting the raw R and S value of an ECDSA signature. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' To create an ECDSA signature, the data first needs to be hashed.  Then the hash
' is signed.

set crypt = CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "SHA256"
crypt.Charset = "utf-8"
crypt.EncodingMode = "base64"

' Hash a string.
hash1 = crypt.HashStringENC("The quick brown fox jumps over the lazy dog")
outFile.WriteLine("hash1 = " & hash1)

' -----------------------------------------------------------
' An ECDSA private key is used for signing.  The public key is for signature verification.
' Load our ECC private key.
' Our private key file contains this:

' 	// -----BEGIN PRIVATE KEY-----
' 	MIGHAgEAMBMGByqGSM49AgEGCCqGSM49AwEHBG0wawIBAQQg3J8q/24D1sEKGdP9
' 	72MGYElLGpw/a56Y3t6pfON3uhShRANCAATlSmoizyhAwoYZAOuFBATl07/1RR54
' 	a1Dzfm16grxJe666AGKR+bSs24hk7TEpaeCTvT8YOOM3l+xKFg7zq6Q9
' 	-----END PRIVATE KEY-----

set privKey = CreateObject("Chilkat.PrivateKey")
success = privKey.LoadPemFile("qa_data/ecc/secp256r1-key-pkcs8.pem")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' Sign the hash..
set prng = CreateObject("Chilkat.Prng")
set ecdsa = CreateObject("Chilkat.Ecc")
ecdsaSigBase64 = ecdsa.SignHashENC(hash1,"base64",privKey,prng)
If (ecdsa.LastMethodSuccess <> 1) Then
    outFile.WriteLine(ecdsa.LastErrorText)
    WScript.Quit
End If

' The ECDSA signature is ASN.1 that contains a sequence of 2 large integers (r and s)
' For example:
' SEQUENCE (2 elem)
'   INTEGER (255 bit) 792134D9B4AD82D5431ED03835A88E2596EB35E5B13054BD9B05A0069281ACC9
'   INTEGER (255 bit) 481E758CC1E3CBF825537EC3D9A2CA627E5FAD1137BBEA65DF38658DCB0A9ED5

outFile.WriteLine("Base64 ECDSA signature = " & ecdsaSigBase64)

' If the raw R and S values are needed, here's how to get them:
set asn = CreateObject("Chilkat.Asn")
success = asn.LoadEncoded(ecdsaSigBase64,"base64")
If (success = 0) Then
    outFile.WriteLine(asn.LastErrorText)
    WScript.Quit
End If

' The R and X will be in hexidecimal in the XML.
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(asn.AsnToXml())
outFile.WriteLine(xml.GetXml())

' The XML looks like this:
' <sequence>
' <int>792134D9B4AD82D5431ED03835A88E2596EB35E5B13054BD9B05A0069281ACC9</int>
' <int>481E758CC1E3CBF825537EC3D9A2CA627E5FAD1137BBEA65DF38658DCB0A9ED5</int>
' </sequence>

' Copy raw R and S hex values into a Chilkat BinData object.
set bd = CreateObject("Chilkat.BinData")
r = xml.GetChildContent("int[0]")
s = xml.GetChildContent("int[1]")
success = bd.AppendEncoded(r,"hex")
success = bd.AppendEncoded(s,"hex")

outFile.WriteLine("Number of bytes in bd: " & bd.NumBytes)

outFile.Close