(VBScript) Generate an ECC Key

Demonstrates how to generate an ECC key.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' All Chilkat classes can be unlocked at once at the beginning of a program
' by calling UnlockBundle.  It requires a Bundle unlock code.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Global")
set chilkatGlob = CreateObject("Chilkat.Global")
success = chilkatGlob.UnlockBundle("Anything for 30-day trial.")
If (success <> 1) Then
    outFile.WriteLine(chilkatGlob.LastErrorText)
    WScript.Quit
End If

' Create a Fortuna PRNG and seed it with system entropy.
' This will be our source of random data for generating the ECC private key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Prng")
set fortuna = CreateObject("Chilkat.Prng")
entropy = fortuna.GetEntropy(32,"base64")
success = fortuna.AddEntropy(entropy,"base64")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ecc")
set ecc = CreateObject("Chilkat.Ecc")

' Generate a random ECC private key on the secp256r1 curve.
' Chilkat also supports other curves, such as secp384r1, secp521r1, and secp256k1.

' privKey is a Chilkat.PrivateKey
Set privKey = ecc.GenEccKey("secp256r1",fortuna)
If (ecc.LastMethodSuccess <> 1) Then
    outFile.WriteLine(ecc.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(privKey.GetXml())

' Save the private key to PKCS8 encrypted PEM
' (The private key can be saved in a variety of different formats. See the online reference documentation.)
success = privKey.SavePkcs8EncryptedPemFile("pemPassword","myPemFiles/eccKey123.pem")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
End If

outFile.WriteLine("finished.")

outFile.Close