Chilkat Examples

ChilkatHOMEAndroid™Classic ASPCC++C#Mono C#.NET Core C#C# UWP/WinRTDataFlexDelphi ActiveXDelphi DLLVisual FoxProJavaLianjaMFCObjective-CPerlPHP ActiveXPHP ExtensionPowerBuilderPowerShellPureBasicCkPythonChilkat2-PythonRubySQL ServerSwift 2Swift 3/4TclUnicode CUnicode C++Visual Basic 6.0VB.NETVB.NET UWP/WinRTVBScriptXojo PluginNode.jsExcelGo

VBScript Web API Examples

Primary Categories

AWS Translate
Activix CRM
Adyen
Amazon MWS
Azure Maps
Azure Monitor
Azure OAuth2
Azure Storage Accounts
Bluzone
CardConnect
ClickBank
Clickatell
Cloudfare
DocuSign
ETrade
Etsy
Facebook
GeoOp
GetHarvest
Jira
MYOB

Magento
Microsoft Calendar
Microsoft Group
Microsoft Tasks and Plans
Okta OAuth/OIDC
OneLogin OIDC
PayPal
Peoplevox
Populi
QuickBooks
SOAP finkok.com
Shippo
Shopify
Stripe
SugarCRM
Trello
Twitter
VoiceBase
Vonage
Walmart
Walmart v3
Xero
eBay
effectconnect

 

 

 

(VBScript) eBay -- Upload Bulk Data using FileTransferService

Demonstrates how to upload your data file using the eBay File Transfer API.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Use a previously obtained access token.  The token should look something like this:
' "AgAAAA**AQA ..."
accessToken = "EBAY_ACCESS_TOKEN"

set http = CreateObject("Chilkat_9_5_0.Http")

apiCall = "uploadFile"
fileAttachmentUuid = "<urn:uuid:bb47b86a237311e793ae92361f002671>"
xmlUuid = "<urn:uuid:bb47b766237311e793ae92361f002671>"

set req = CreateObject("Chilkat_9_5_0.HttpRequest")

req.HttpVerb = "POST"
req.Path = "/FileTransferService"

set sbContentType = CreateObject("Chilkat_9_5_0.StringBuilder")
success = sbContentType.Append("multipart/related; type=""application/xop+xml""; start=""XMLUUID""; start-info=""text/xml""")
replaceCount = sbContentType.Replace("XMLUUID",xmlUuid)
req.ContentType = sbContentType.GetAsString()

req.AddHeader "X-EBAY-SOA-SERVICE-NAME","FileTransferService"
req.AddHeader "X-EBAY-SOA-OPERATION-NAME",apiCall
req.AddHeader "X-EBAY-SOA-SECURITY-TOKEN",accessToken
req.AddHeader "X-EBAY-SOA-REQUEST-DATA-FORMAT","XML"
req.AddHeader "X-EBAY-SOA-RESPONSE-DATA-FORMAT","XML"
req.AddHeader "User-Agent","AnythingYouWant"

pathToFileOnDisk1 = "qa_data/ebay/uploadFileRequest.xml"
success = req.AddFileForUpload("uploadFileRequest.xml",pathToFileOnDisk1)
If (success <> 1) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

pathToFileOnDisk2 = "qa_data/ebay/BulkDataExchangeRequests.gz"
success = req.AddFileForUpload("BulkDataExchangeRequests.gz",pathToFileOnDisk2)
If (success <> 1) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

' Add sub-headers for each file in the request.
success = req.AddSubHeader(0,"Content-Type","application/xop+xml; charset=UTF-8; type=""text/xml""")
success = req.AddSubHeader(0,"Content-Transfer-Encoding","binary")
success = req.AddSubHeader(0,"Content-ID",xmlUuid)
success = req.AddSubHeader(1,"Content-Type","application/octet-stream")
success = req.AddSubHeader(1,"Content-Transfer-Encoding","binary")
success = req.AddSubHeader(1,"Content-ID",fileAttachmentUuid)

' resp is a Chilkat_9_5_0.HttpResponse
Set resp = http.SynchronousRequest("storage.sandbox.ebay.com",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & resp.StatusCode)

set xml = CreateObject("Chilkat_9_5_0.Xml")
success = xml.LoadXml(resp.BodyStr)

If (resp.StatusCode <> 200) Then
    outFile.WriteLine(xml.GetXml())
    outFile.WriteLine("Failed.")

    WScript.Quit
End If

' We still may have a failure.  The XML needs to be checked.
' A failed response might look like this:

' 	<?xml version="1.0" encoding="UTF-8" ?>
' 	<uploadFileResponse xmlns="http://www.ebay.com/marketplace/services">
' 	    <ack>Failure</ack>
' 	    <errorMessage>
' 	        <error>
' 	            <errorId>1</errorId>
' 	            <domain>Marketplace</domain>
' 	            <severity>Error</severity>
' 	            <category>Application</category>
' 	            <message>Task Reference Id is invalid</message>
' 	            <subdomain>FileTransfer</subdomain>
' 	        </error>
' 	    </errorMessage>
' 	    <version>1.1.0</version>
' 	    <timestamp>2017-04-18T01:05:27.475Z</timestamp>
' 	</uploadFileResponse>

' A successful response looks like this:

' 	<?xml version="1.0" encoding="UTF-8" ?>
' 	<uploadFileResponse xmlns="http://www.ebay.com/marketplace/services">
' 	    <ack>Success</ack>
' 	    <version>1.1.0</version>
' 	    <timestamp>2017-04-18T01:22:47.853Z</timestamp>
' 	</uploadFileResponse>

outFile.WriteLine(xml.GetXml())

' Get the "ack" to see if it's "Failure" or "Success"
If (xml.ChildContentMatches("ack","Success",0)) Then
    outFile.WriteLine("Success.")
Else
    outFile.WriteLine("Failure.")
End If


outFile.Close

 

© 2000-2019 Chilkat Software, Inc. All Rights Reserved.