(VBScript) eBay -- Download Data using FileTransferService

Demonstrates how to download a data file using the eBay File Transfer API.

Note: This example requires Chilkat v9.5.0.67 or later.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Use a previously obtained access token.  The token should look something like this:
' "AgAAAA**AQA ..."
accessToken = "EBAY_ACCESS_TOKEN"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")

req.HttpVerb = "POST"
req.Path = "/FileTransferService"
req.ContentType = "application/xml"

' Build the XML body for the request.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "downloadFileRequest"
success = xml.AddAttribute("xmlns","http://www.ebay.com/marketplace/services")
xml.UpdateChildContent "taskReferenceId","50013004806"
xml.UpdateChildContent "fileReferenceId","50015579016"

success = req.LoadBodyFromString(xml.GetXml(),"utf-8")

' The XML body looks like this:

' 	<?xml version="1.0" encoding="UTF-8"?>
' 	<downloadFileRequest xmlns="http://www.ebay.com/marketplace/services">
' 	<taskReferenceId>50013004806</taskReferenceId>
' 	<fileReferenceId>50015579016</fileReferenceId>
' 	</downloadFileRequest>

req.AddHeader "X-EBAY-SOA-OPERATION-NAME","downloadFile"
req.AddHeader "X-EBAY-SOA-SECURITY-TOKEN",accessToken

' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest("storage.sandbox.ebay.com",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

statusCode = resp.StatusCode
outFile.WriteLine("Response status code = " & statusCode)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set responseBody = CreateObject("Chilkat.BinData")
success = resp.GetBodyBd(responseBody)

' We can save the response body to a file for examination if we get an unanticipated response.  
' (It's binary, so it won't open well in a text editor.)
success = responseBody.WriteFile("qa_output/response.mime")

If (statusCode <> 200) Then
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' The response body looks like this:

' 	--MIMEBoundaryurn_uuid_2B668636C1E17A4D4114925305818684241
' 	Content-Type: application/xop+xml; charset=utf-8; type="text/xml"
' 	Content-Transfer-Encoding: binary
' 	Content-ID: <0.urn:uuid:2B668636C1E17A4D4114925305818684242>
' 
' 	<?xml version='1.0' encoding='UTF-8'?>
' 	<downloadFileResponse xmlns="http://www.ebay.com/marketplace/services">
' 	<ack>Success</ack>
' 	<version>1.1.0</version>
' 	<timestamp>2017-04-18T15:49:41.868Z</timestamp>
' 	<fileAttachment>
' 	    <Size>587</Size>
' 	    <Data>
'                 <xop:Include xmlns:xop="http://www.w3.org/2004/08/xop/include" href="cid:urn:uuid:A37C3C73E994C267F11492530585522"/>
' 	    </Data>
' 	</fileAttachment>
' 	</downloadFileResponse>
' 	--MIMEBoundaryurn_uuid_2B668636C1E17A4D4114925305818684241
' 	Content-Type: application/zip
' 	Content-Transfer-Encoding: binary
' 	Content-ID: <urn:uuid:A37C3C73E994C267F11492530585522>
' 
' 	<the binary bytes of the zip start here...>
' 

' Load the binary response into a MIME object.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mime")
set mime = CreateObject("Chilkat.Mime")
success = mime.LoadMimeBd(responseBody)
If (success <> 1) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

' Make sure we have 2 sub-parts.  The 1st sub-part is the XML response, the 2nd sub-part
' is the zip containing the data.

' Note: The 2nd sub-part can be a "zip" or "gzip".  These are two different file formats.
' A zip is indicated with a Content-Type header equal to "application/zip",
' whereas a gzip is indicated with a Content-Type header equal to "application/x-gzip"
If (mime.NumParts <> 2) Then
    outFile.WriteLine("Expected the MIME to have 2 parts.")
    outFile.WriteLine("NumParts = " & mime.NumParts)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Get the XML from the 1st MIME sub-part.
' part0 is a Chilkat.Mime
Set part0 = mime.GetPart(0)
downloadResponseXml = part0.GetBodyDecoded()
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xmlResp = CreateObject("Chilkat.Xml")
success = xmlResp.LoadXml(downloadResponseXml)
outFile.WriteLine("Download Response XML:")
outFile.WriteLine(xmlResp.GetXml())

outFile.WriteLine("----")

' Now get the zip from the second part (index=1), unzip, and examine..
' part1 is a Chilkat.Mime
Set part1 = mime.GetPart(1)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set zipData = CreateObject("Chilkat.BinData")
' This example requires Chilkat v9.5.0.67 or later.
' The GetBodyBd method was added in v9.5.0.67.
success = part1.GetBodyBd(zipData)

' Check to see if we have a zip or gzip.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbContentType = CreateObject("Chilkat.StringBuilder")
success = sbContentType.Append(part1.ContentType)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xmlFromZip = CreateObject("Chilkat.Xml")

If (sbContentType.Contains("gzip",0) = 1) Then
    ' This is a gzip compressed file.
    ' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Gzip")
    set gzip = CreateObject("Chilkat.Gzip")

    ' in-place uncompress the data.
    ' Note: The UncompressBd method was added in Chilkat v9.5.0.67
    success = gzip.UncompressBd(zipData)
    If (success <> 1) Then
        outFile.WriteLine(gzip.LastErrorText)
        WScript.Quit
    End If

    success = xmlFromZip.LoadXml(zipData.GetString("utf-8"))

Else
    ' This is a zip archive.

    ' Load the body into a Zip object.
    ' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Zip")
    set zip = CreateObject("Chilkat.Zip")
    success = zip.OpenBd(zipData)
    If (success <> 1) Then
        outFile.WriteLine(zip.LastErrorText)
        WScript.Quit
    End If

    ' Save the .zip to a file (so we can examine it for debugging if something is not as expected)
    success = zipData.WriteFile("qa_output/ebay_data.zip")

    ' The zip should contain a single XML file.
    If (zip.NumEntries <> 1) Then
        outFile.WriteLine("Expected the .zip to have 1 entry.")
        outFile.WriteLine("NumEntries = " & zip.NumEntries)
        outFile.WriteLine("Failed.")
        WScript.Quit
    End If

    ' entry is a Chilkat.ZipEntry
    Set entry = zip.GetEntryByIndex(0)

    success = xmlFromZip.LoadXml(entry.UnzipToString(0,"utf-8"))

End If

outFile.WriteLine("XML contained in the zip:")
outFile.WriteLine(xmlFromZip.GetXml())
outFile.WriteLine("----")

outFile.WriteLine("Success.")

outFile.Close