VBScript

Duo Auth API - Auth

See more Duo Auth MFA Examples

The /auth endpoint performs second-factor authentication for a user by sending a push notification to the user's smartphone app, verifying a passcode, or placing a phone call. It is also used to send the user a new batch of passcodes via SMS. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

integrationKey = "DIMS3V5QDVG9J9ABRXC4"
secretKey = "HWVQ46nubLBxhnRlKddTltWIi3hL0fIQF2qTvLab"

set http = CreateObject("Chilkat.Http")

http.Accept = "application/json"

' Use your own hostname here:
url = "https://api-a03782e1.duosecurity.com/auth/v2/auth"

' This example requires Chilkat v9.5.0.89 or greater because Chilkat will automatically
' generate and send the HMAC signature for the requires based on the integration key and secret key.
http.Login = integrationKey
http.Password = secretKey

set req = CreateObject("Chilkat.HttpRequest")
req.AddParam "username","matt"
req.AddParam "factor","push"
' The device ID can be obtained from the preauth response.  See Duo Preauth Example
req.AddParam "device","DP6GYVTQ5NK82BMR851F"

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpReq(url,req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("status code = " & resp.StatusCode)

set json = CreateObject("Chilkat.JsonObject")
success = json.Load(resp.BodyStr)
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

' Sample successful output:

' status code = 200

' {
'   "response": {
'     "result": "allow",
'     "status": "allow",
'     "status_msg": "Success. Logging you in..."
'   },
'   "stat": "OK"
' }

' Sample code to parse the above JSON response..

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

responseResult = json.StringOf("response.result")
responseStatus = json.StringOf("response.status")
responseStatus_msg = json.StringOf("response.status_msg")
stat = json.StringOf("stat")

outFile.Close