(VBScript) DSA Signature Create and Verify

Shows how to create a DSA (DSS) signature for the contents of a file. The first step is to create an SHA-1 hash of the file contents. The hash is signed using the Digital Signature Algorithm and the signature bytes are retrieved as a hex-encoded string.

The 2nd part of the example loads the signature and verifies it against the hash.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

crypt.EncodingMode = "hex"
crypt.HashAlgorithm = "sha-1"

' Return the SHA-1 hash of a file.  The file may be any size.
' The Chilkat Crypt component will stream the file when 
' computing the hash, keeping the memory usage constant
' and reasonable.
' The 20-byte SHA-1 hash is returned as a hex-encoded string.
hashStr = crypt.HashFileENC("hamlet.xml")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Dsa")
set dsa = CreateObject("Chilkat.Dsa")

' Load a DSA private key from a PEM file.  Chilkat DSA
' provides the ability to load and save DSA public and private
' keys from encrypted or non-encrypted PEM or DER.
' The LoadText method is for convenience only.  You may
' use any means to load the contents of a PEM file into
' a string.

pemPrivateKey = dsa.LoadText("dsa_priv.pem")
success = dsa.FromPem(pemPrivateKey)
If (success <> 1) Then
    outFile.WriteLine(dsa.LastErrorText)
    WScript.Quit
End If

' You may optionally verify the key to ensure that it is a valid
' DSA key.
success = dsa.VerifyKey()
If (success <> 1) Then
    outFile.WriteLine(dsa.LastErrorText)
    WScript.Quit
End If

' Load the hash to be signed into the DSA object:
success = dsa.SetEncodedHash("hex",hashStr)
If (success <> 1) Then
    outFile.WriteLine(dsa.LastErrorText)
    WScript.Quit
End If

' Now that the DSA object contains both the private key and hash,
' it is ready to create the signature:
success = dsa.SignHash()
If (success <> 1) Then
    outFile.WriteLine(dsa.LastErrorText)
    WScript.Quit
End If

' If SignHash is successful, the DSA object contains the
' signature.  It may be accessed as a hex or base64 encoded
' string.  (It is also possible to access directly in byte array form via
' the "Signature" property.)
hexSig = dsa.GetEncodedSignature("hex")
outFile.WriteLine("Signature:")
outFile.WriteLine(hexSig)

' -----------------------------------------------------------
' Step 2: Verify the DSA Signature
' -----------------------------------------------------------

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Dsa")
set dsa2 = CreateObject("Chilkat.Dsa")

' Load the DSA public key to be used for verification:

pemPublicKey = dsa2.LoadText("dsa_pub.pem")
success = dsa2.FromPublicPem(pemPublicKey)
If (success <> 1) Then
    outFile.WriteLine(dsa2.LastErrorText)
    WScript.Quit
End If

' Load the hash to be verified against the signature.
success = dsa2.SetEncodedHash("hex",hashStr)
If (success <> 1) Then
    outFile.WriteLine(dsa2.LastErrorText)
    WScript.Quit
End If

' Load the signature:
success = dsa2.SetEncodedSignature("hex",hexSig)
If (success <> 1) Then
    outFile.WriteLine(dsa2.LastErrorText)
    WScript.Quit
End If

' Verify:
success = dsa2.Verify()
If (success <> 1) Then
    outFile.WriteLine(dsa2.LastErrorText)
Else
    outFile.WriteLine("DSA Signature Verified!")
End If


outFile.Close