(VBScript) Dropbox: OAuth2 Authorization to Obtain an Access Token

See more Dropbox Examples

This example runs the OAuth 2.0 authorization flow that lets the user sign in to Dropbox and authorize your app.

Note: This example requires Chilkat v10.1.2 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For more information about the OAuth2, see OAuth 2.0 Authorization Flow

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.OAuth2")
set oauth2 = CreateObject("Chilkat.OAuth2")

' The port should match the Authorized Redirect URL in your Dropbox app, 
' which would look like "http://localhost:3017/"
oauth2.ListenPort = 3017

' IMPORTANT: One of the OAuth2 redirect URIs for your Dropbox app must be
' exactly this string:  http://localhost:3017/

oauth2.AuthorizationEndpoint = "https://www.dropbox.com/oauth2/authorize"
oauth2.TokenEndpoint = "https://api.dropboxapi.com/oauth2/token"

' Replace this with your actual Dropbox App Key
oauth2.ClientId = "DROPBOX_APP_KEY"

' This is for Require Proof Key for Code Exchange (PKCE)
' See OAuth2 PKCE Explained
oauth2.CodeChallenge = 1
oauth2.CodeChallengeMethod = "S256"

' Add token_access_type=offline to also get a refresh token in the response
success = oauth2.AddAuthQueryParam("token_access_type","offline")

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("url = " & url)

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' Wait for the user to approve or deny authorization in the browser.
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response - The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    outFile.WriteLine("No response from the browser!")
    WScript.Quit
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    outFile.WriteLine("OAuth2 failed to complete.")
    outFile.WriteLine(oauth2.FailureInfo)
    WScript.Quit
End If

If (oauth2.AuthFlowState = 4) Then
    outFile.WriteLine("OAuth2 authorization was denied.")
    outFile.WriteLine(oauth2.AccessTokenResponse)
    WScript.Quit
End If

If (oauth2.AuthFlowState <> 3) Then
    outFile.WriteLine("Unexpected AuthFlowState:" & oauth2.AuthFlowState)
    WScript.Quit
End If

outFile.WriteLine("OAuth2 authorization granted!")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = 0

outFile.WriteLine("Access Token Response = " & json.Emit())

' A sample access token response:

' {
'   "access_token": "...",
'   "token_type": "bearer",
'   "expires_in": 14399,
'   "refresh_token": "...",
'   "scope": "account_info.read",
'   "uid": "562542581",
'   "account_id": "dbid:AACQhDS0E3_Vb72Ynd0F-GxGWdTI2qcTHzA"
' }

outFile.WriteLine("Access Token = " & oauth2.AccessToken)

' Save the JSON access token response to a file for subsequent use..
success = json.WriteFile("qa_data/tokens/dropbox.json")

outFile.Close