(VBScript) Dropbox: Get Space Usage

Demonstrates how to get the Dropbox space usage information for the current user's account.

For more information, see https://www.dropbox.com/developers/documentation/http/documentation#users-get_space_usage

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the www.dropbox.com endpoint.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("api.dropboxapi.com",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.AddHeader("Authorization","Bearer DROPBOX-ACCESS-TOKEN")

responseStr = rest.FullRequestNoBody("POST","/2/users/get_space_usage")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Success is indicated by a 200 response status code.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonResponse = CreateObject("Chilkat.JsonObject")
success = jsonResponse.Load(responseStr)

jsonResponse.EmitCompact = 0
outFile.WriteLine(jsonResponse.Emit())

' {
'   "used": 3032115,
'   "allocation": {
'     ".tag": "individual",
'     "allocated": 2147483648
'   }
' }
' 

outFile.Close