(VBScript) Dropbox File Streaming Upload

Upload a file to Drobox using a file stream. This example can upload files up to 150MB. Larger files must be uploaded with an upload session (upload_session/start).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' A Dropbox access token should have been previously obtained.
' Dropbox access tokens do not expire.
' See Dropbox Access Token.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to Dropbox
success = rest.Connect("content.dropboxapi.com",443,1,1)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Add request headers.
success = rest.AddHeader("Content-Type","application/octet-stream")
success = rest.AddHeader("Authorization","Bearer DROPBOX_ACCESS_TOKEN")

' The upload "parameters" contained in JSON passed in an HTTP request header.
' This is the JSON to be added in this example:
' { 
'    "path": "/Homework/lit/hamlet.xml",
'    "mode": "add",
'    "autorename": true,
'    "mute": false
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.AppendString("path","/Homework/lit/hamlet.xml")
success = json.AppendString("mode","add")
success = json.AppendBool("autorename",1)
success = json.AppendBool("mute",0)
success = rest.AddHeader("Dropbox-API-Arg",json.Emit())

' Almost ready to go...
' Let's setup a file stream to point to a file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Stream")
set fileStream = CreateObject("Chilkat.Stream")
fileStream.SourceFile = "qa_data/xml/hamlet.xml"

' Do the upload.  The URL is https://content.dropboxapi.com/2/files/upload.
' We already connected to content.dropboxapi.com using TLS (i.e. HTTPS),
' so now we only need to specify the path "/2/files/upload".

' Note: The file is streamed directly from disk.  (The entire
' file will not be loaded into memory.)
responseStr = rest.FullRequestStream("POST","/2/files/upload",fileStream)
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, Dropbox responds with a 200 response code.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' The response is JSON.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonResp = CreateObject("Chilkat.JsonObject")
jsonResp.EmitCompact = 0
success = jsonResp.Load(responseStr)

' Show the JSON response.
outFile.WriteLine(jsonResp.Emit())

' Returns JSON that looks like this:
' { 
'   "name": "hamlet.xml",
'   "path_lower": "/homework/lit/hamlet.xml",
'   "path_display": "/Homework/lit/hamlet.xml",
'   "id": "id:74FkdeNuyKAAAAAAAAAAAQ",
'   "client_modified": "2016-06-02T23:19:00Z",
'   "server_modified": "2016-06-02T23:19:00Z",
'   "rev": "9482db15f",
'   "size": 279658
' }

' Sample code to get data from the JSON response:
size = jsonResp.IntOf("size")
outFile.WriteLine("size = " & size)

rev = jsonResp.StringOf("rev")
outFile.WriteLine("rev = " & rev)

clientModified = jsonResp.StringOf("client_modified")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set ckdt = CreateObject("Chilkat.CkDateTime")
success = ckdt.SetFromTimestamp(clientModified)
bLocalTime = 1
' dt is a Chilkat.DtObj
Set dt = ckdt.GetDtObj(bLocalTime)
outFile.WriteLine(dt.Day & "/" & dt.Month & "/" & dt.Year & " " & dt.Hour & ":" & dt.Minute)


outFile.Close