VBScript

Docusign Refresh OAuth2 Access Token

See more DocuSign Examples

Demonstrates how to refresh a Docusign OAuth2 access token. The refresh does not require user interaction via a web browser. If an access token expires (typically with a 401 response code), a new access token can be automatically obtained by using the code in this example. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Docusign OAuth2 Access Token

set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/docusign.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load docusign.json")
    WScript.Quit
End If

' The access token JSON looks like this:

' {
'   "access_token": "eyJ0eXA....YQyig",
'   "token_type": "Bearer",
'   "refresh_token": "eyJ0eXA....auE3eHKg",
'   "expires_in": 28800
' }

set oauth2 = CreateObject("Chilkat.OAuth2")

' For the developer sandbox environment, the token endpoint is https://account-d.docusign.com/oauth/token
' For the production platform, the token endpoint is https://account.docusign.com/oauth/token
oauth2.TokenEndpoint = "https://account-d.docusign.com/oauth/token"

' Replace these with actual values.
' The client ID is also known as the "integration key" in Docusign.
oauth2.ClientId = "MY_DOCUSIGN_CLIENT_ID"
' This is your secret key for the authorization code grant.
oauth2.ClientSecret = "MY_DOCUSIGN_CLIENT_SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("New access token: " & oauth2.AccessToken)
outFile.WriteLine("New refresh token: " & oauth2.RefreshToken)

' Update the JSON with the new tokens.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)
success = jsonToken.UpdateString("refresh_token",oauth2.RefreshToken)

' Save the new JSON access token response to a file.
set sbJson = CreateObject("Chilkat.StringBuilder")
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/docusign.json","utf-8",0)

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

outFile.Close