(VBScript) Docusign JSON Web Token (JWT) Grant

Demonstrates how to obtain an access token using the JSON Web Token (JWT) Grant. This is good for service integrations where authorization and authentication is automated and cannot have interactive Docusign account owner interaction. Consent for the access is obtained beforehand in various ways. See Obtaining Consent.

For more information, see https://developers.docusign.com/esign-rest-api/guides/authentication/oauth2-jsonwebtoken

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' 1. Assume we have already requested and obtained application consent.
'    (See Request Docusign Application Consent
' 
' 2. Create a JWT Token.
' 
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set privKey = CreateObject("Chilkat.PrivateKey")

' Load an RSA private key from a PEM file.
success = privKey.LoadPemFile("qa_data/pem/docusign_private_rsa_key.pem")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jwt")
set jwt = CreateObject("Chilkat.Jwt")

' Build the JOSE header
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jose = CreateObject("Chilkat.JsonObject")
' Use RS256.  Pass the string "RS384" or "RS512" to use RSA with SHA-384 or SHA-512.
success = jose.AppendString("alg","RS256")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set claims = CreateObject("Chilkat.JsonObject")

' Replace these with actual values.
' The client ID is also known as the "integration key" in Docusign.
success = claims.AppendString("iss","MY_DOCUSIGN_CLIENT_ID")
' In your DocuSign Admin/Account/UserProfile, this is the API Username, such as 14612117-2530-4982-8c49-ba8766303272
success = claims.AppendString("sub","DOCUSIGN_USER_ID")
success = claims.AppendString("aud","account-d.docusign.com")
success = claims.AppendString("scope","signature")

' Set the timestamp of when the JWT was created to now.
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

' Create the JWT token.  This is where the RSA signature is created.
token = jwt.CreateJwtPk(jose.Emit(),claims.Emit(),privKey)

outFile.WriteLine(token)

' Do the following CURL statement to get the response JSON which contains the access token.
' curl --data "grant_type=urn:ietf:params:oauth:grant-type:jwt-bearer&assertion=YOUR_JSON_WEB_TOKEN" 
'      --request POST https://account-d.docusign.com/oauth/token
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.AddParam "grant_type","urn:ietf:params:oauth:grant-type:jwt-bearer"
req.AddParam "assertion",token

' resp is a Chilkat.HttpResponse
Set resp = http.PostUrlEncoded("https://account-d.docusign.com/oauth/token",req)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("response status = " & resp.StatusCode)
If (resp.StatusCode <> 200) Then
    outFile.WriteLine(resp.BodyStr)
    outFile.WriteLine("Failed.")
Else
    ' Save the access token to a file for use in subsequent requests..
    ' (Or you may simply persiste the access token in memory for your applicaton to use for subsequent REST API calls..)
    success = resp.SaveBodyText(1,"qa_data/tokens/docusign.json")
    outFile.WriteLine(resp.BodyStr)
    outFile.WriteLine("Success.")
End If


outFile.Close