(VBScript) Verify DKIM-Signature Headers in Downloaded Email

Downloads email from an IMAP server and verifies the DKIM-Signature header(s) in each email, if present.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server, login, select mailbox..
' Use TLS 
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.someMailServer.com")
If (success = 1) Then
    success = imap.Login("myLogin","myPassword")
    If (success = 1) Then
        success = imap.SelectMailbox("Inbox")
    End If

End If

If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Dkim")
set dkim = CreateObject("Chilkat.Dkim")

' Download a max of 10 emails and verify any DKIM-Signature headers
' that are present.

' Download emails by sequence numbers (not UIDs).
bUid = 0

n = imap.NumMessages
If (n > 10) Then
    n = 10
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0

' To verify DKIM-Signature headers, we need the exact unmodified MIME bytes of each email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set mimeData = CreateObject("Chilkat.BinData")
seqNum = 1
Do While seqNum <= n
    ' The FetchSingleBd method was introduced in v9.5.0.76
    success = imap.FetchSingleBd(seqNum,bUid,mimeData)
    If (success <> 1) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

    ' Get the number of DKIM-Signature headers.
    numDkim = dkim.NumDkimSigs(mimeData)

    ' Verify each..
    j = 0
    Do While j < numDkim
        outFile.WriteLine("------ DKIM Signature " & j)

        success = dkim.DkimVerify(j,mimeData)
        If (success <> 1) Then
            outFile.WriteLine("Not valid.")
        Else
            outFile.WriteLine("valid.")
        End If

        ' Show the additional information about the signature verification
        success = json.Load(dkim.VerifyInfo)
        outFile.WriteLine(json.Emit())

        ' The JSON contains information such as this:

        ' 	{
        ' 	  "domain": "amazonses.com",
        ' 	  "selector": "7v7vs6w47njt4pimodk5mmttbegzsi6n",
        ' 	  "publicKey": "MIGfMA0GCSqG...v2GvWPqGHz6uqeQIDAQAB",
        ' 	  "canonicalization": "relaxed/simple",
        ' 	  "algorithm": "rsa-sha256",
        ' 	  "signedHeaders": "Subject:From:To:Date:Mime-Version:Content-Type:References:Message-Id:Feedback-ID",
        ' 	  "verified": "yes"
        ' 	}

        j = j + 1
    Loop
    seqNum = seqNum + 1
Loop

success = imap.Disconnect()

outFile.Close