(VBScript) Renew a DigiCert Certificate from an EST-enabled profile

Demonstrates how to renew a certificate from an EST-enabled profile in DigiCert​​®​​ Trust Lifecycle Manager. (The certificate must be within the renewal window configured in the certificate profile. The CSR must have same Subject DN values as the original certificate.)

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The example below duplicates the following OpenSSL commands:
' 
' # Name of certificate as argument 1
' 
' # Make new key
' openssl ecparam -name prime256v1 -genkey -noout -out ${1}.key.pem
' 
' # Make csr
' openssl req -new -sha256 -key ${1}.key.pem -out ${1}.p10.csr -subj "/CN=${1}"
' 
' # Request new cert
' curl -v --cacert data/ca.pem --cert data/${1}.pem --key data/${1}.key.pem 
'     --data-binary @${1}.p10.csr -o ${1}.p7.b64 -H "Content-Type: application/pkcs10" https://clientauth.demo.one.digicert.com/.well-known/est/IOT/simplereenroll
' 
' # Convert to PEM
' openssl base64 -d -in ${1}.p7.b64 | openssl pkcs7 -inform DER -outform PEM -print_certs -out ${1}.pem

' ------------------------------------------------------------------------------------------------------------------

' Create a Fortuna PRNG and seed it with system entropy.
' This will be our source of random data for generating the ECC private key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Prng")
set fortuna = CreateObject("Chilkat.Prng")
entropy = fortuna.GetEntropy(32,"base64")
success = fortuna.AddEntropy(entropy,"base64")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ecc")
set ec = CreateObject("Chilkat.Ecc")

' Generate a random EC private key on the prime256v1 curve.
' privKey is a Chilkat.PrivateKey
Set privKey = ec.GenEccKey("prime256v1",fortuna)
If (ec.LastMethodSuccess <> 1) Then
    outFile.WriteLine(ec.LastErrorText)
    WScript.Quit
End If

' Create the CSR object and set properties.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Csr")
set csr = CreateObject("Chilkat.Csr")

' Specify your CN
csr.CommonName = "mysubdomain.mydomain.com"

' Create the CSR using the private key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdCsr = CreateObject("Chilkat.BinData")
success = csr.GenCsrBd(privKey,bdCsr)
If (success = 0) Then
    outFile.WriteLine(csr.LastErrorText)

    WScript.Quit
End If

' Save the private key and CSR to files.
success = privKey.SavePkcs8EncryptedPemFile("password","c:/temp/qa_output/ec_privkey.pem")

success = bdCsr.WriteFile("c:/temp/qa_output/csr.pem")

' ----------------------------------------------------------------------
' Now do the CURL request to POST the CSR and get the new certificate.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set tlsClientCert = CreateObject("Chilkat.Cert")
success = tlsClientCert.LoadFromFile("data/myTlsClientCert.pem")
If (success = 0) Then
    outFile.WriteLine(tlsClientCert.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdTlsClientCertPrivKey = CreateObject("Chilkat.BinData")
success = bdTlsClientCertPrivKey.LoadFile("data/myTlsClientCert.key.pem")
If (success = 0) Then
    outFile.WriteLine("Failed to load data/myTlsClientCert.key.pem")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set tlsClientCertPrivKey = CreateObject("Chilkat.PrivateKey")
success = tlsClientCertPrivKey.LoadAnyFormat(bdTlsClientCertPrivKey,"")
If (success = 0) Then
    outFile.WriteLine(tlsClientCertPrivKey.LastErrorText)
    WScript.Quit
End If

success = tlsClientCert.SetPrivateKey(tlsClientCertPrivKey)
If (success = 0) Then
    outFile.WriteLine(tlsClientCert.LastErrorText)
    WScript.Quit
End If

success = http.SetSslClientCert(tlsClientCert)

http.RequireSslCertVerify = 1

' The body of the HTTP request contains the binary CSR.
' resp is a Chilkat.HttpResponse
Set resp = http.PBinaryBd("POST","https://clientauth.demo.one.digicert.com/.well-known/est/IOT/simplereenroll",bdCsr,"application/pkcs10",0,0)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

If (resp.StatusCode <> 200) Then
    outFile.WriteLine("response status code = " & resp.StatusCode)
    outFile.WriteLine(resp.BodyStr)
    outFile.WriteLine("Failed")

    WScript.Quit
End If

' The response is the Base64 DER of the new certificate.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set myNewCert = CreateObject("Chilkat.Cert")
success = myNewCert.LoadFromBase64(resp.BodyStr)
If (success = 0) Then
    outFile.WriteLine(myNewCert.LastErrorText)
    outFile.WriteLine("Cert data = " & resp.BodyStr)
    outFile.WriteLine("Failed.")

    WScript.Quit
End If

success = myNewCert.SaveToFile("c:/temp/qa_output/myNewCert.cer")
If (success = 0) Then
    outFile.WriteLine(myNewCert.LastErrorText)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close