(VBScript) How to Tell if a File is .p7m or .p7s

This example explains how to detect if a file is a .p7m or .p7s. It provides as solution to the following problem:

Sometimes people submit P7S/P7M with wrong extensions. Can I check if file is P7S or P7M with Chilkat?

Also see What is a P7M or P7S File?

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' A .p7m or .p7s file is binary and contains PKCS7.
' PKCS7 is ASN.1, and always begins with a SEQUENCE tag (a byte equal to 0x30)
' followed by an encoded length.
' If the file is larger than 128 bytes (and it SHOULD be), the encoded length will begin with either 0x80, 0x81, 0x82, or 0x83.
' It can also begin with 0x84, but only for very large files (where the length is too large for 3 bytes).
' See How ASN.1 Encodes Lengths

' Therefore, if we have a file that might be .p7m or .p7s, we can check by
' examining the 1st 2 bytes of the file.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")

success = bd.LoadFile("qa_data/p7m/a.p7m")
If (success = 0) Then
    outFile.WriteLine("Failed to load the file.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
success = sb.Append(bd.GetEncodedChunk(0,2,"hex"))

caseSensitive = 1
If (sb.ContentsEqual("3080",caseSensitive) Or sb.ContentsEqual("3081",caseSensitive) Or sb.ContentsEqual("3082",caseSensitive) Or sb.ContentsEqual("3083",caseSensitive)) Then
    outFile.WriteLine("This is a .p7m or .p7s file.")
Else
    outFile.WriteLine("This is not a .p7m or .p7s file.")
End If


outFile.Close