VBScript

Decompress Large Text File in Blocks

See more Compression Examples

Decompresses a large text file in blocks, and compares the restored (decompressed) file with the original to make sure it's correct. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First, let's compress a text file.
' We'll then decompress in blocks, and compare the decompressed with the original file.

' Compress a text file:
set compress = CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"

success = compress.CompressFile("qa_data/hamlet.xml","qa_data/hamlet_compressed.dat")
If (success = 0) Then
    outFile.WriteLine(compress.LastErrorText)
    WScript.Quit
End If

set fac = CreateObject("Chilkat.FileAccess")

' Examine the uncompressed and compressed sizes:
originalPath = "qa_data/hamlet.xml"
' Note: The FileSize method returns a signed 32-bit integer.  If the file is potentially larger than 2GB, call FileSizeStr instead to return
' the size of the file as a string, then convert to an integer value.
outFile.WriteLine("uncompressed size: " & fac.FileSize(originalPath))
outFile.WriteLine("compressed size: " & fac.FileSize("qa_data/hamlet_compressed.dat"))

' Decompress in blocks..
set facSrc = CreateObject("Chilkat.FileAccess")
set facDest = CreateObject("Chilkat.FileAccess")

success = facSrc.OpenForRead("qa_data/hamlet_compressed.dat")

' If we compress in 32K chunks, find out how many blocks there will be.
blockSize = 32768
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the decompressed data.
restoredPath = "qa_output/hamlet_restored.xml"
success = facDest.OpenForWrite(restoredPath)
If (success = 0) Then
    outFile.WriteLine(facDest.LastErrorText)
    WScript.Quit
End If

' Assuming numBlocks > 1
compress.FirstChunk = 1
compress.LastChunk = 0

i = 0
Do While i < numBlocks
    compressedBytes = facSrc.ReadBlock(i,blockSize)
    decompressedStr = compress.DecompressString(compressedBytes)

    success = facDest.AppendText(decompressedStr,"utf-8")

    i = i + 1

    compress.FirstChunk = 0
    If (i = (numBlocks - 1)) Then
        compress.LastChunk = 1
    End If

Loop

facSrc.FileClose 
facDest.FileClose 

' Examine the size of the restored file.
outFile.WriteLine("restored size: " & fac.FileSize(restoredPath))

' Compare the contents of the original with the restored.
bEqualContents = fac.FileContentsEqual(restoredPath,originalPath)
outFile.WriteLine("Contents Equal: " & bEqualContents)

outFile.Close