(VBScript) Decompress Large Binary File in Blocks

Decompresses a large binary file in blocks. This example uses BeginDecompressBytes, MoreDecompressBytes, and EndDecompressBytes.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set facSrc = CreateObject("Chilkat.FileAccess")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set facDest = CreateObject("Chilkat.FileAccess")

' Open a previously compressed file for decompressing.
' See Compress Large File in Blocks

success = facSrc.OpenForRead("qa_data/bmp/compressedBmp.dat")
If (success <> 1) Then
    outFile.WriteLine(facSrc.LastErrorText)
    WScript.Quit
End If

' If we compress in 32K chunks, find out how many blocks there will be.
blockSize = 32768
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the decompressed data.
success = facDest.OpenForWrite("qa_output/decompressed.bmp")
If (success <> 1) Then
    outFile.WriteLine(facDest.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Compression")
set compress = CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"

i = 0
Do While i < numBlocks
    compressedBytes = facSrc.ReadBlock(i,blockSize)
    If (i = 0) Then
        decompressedBytes = compress.BeginDecompressBytes(compressedBytes)
    Else
        decompressedBytes = compress.MoreDecompressBytes(compressedBytes)
    End If

    success = facDest.FileWrite(decompressedBytes)

    i = i + 1
Loop

' At the very end, flush any remaining decompressed bytes, if any.
decompressedBytes = compress.EndDecompressBytes()
success = facDest.FileWrite(decompressedBytes)

facSrc.FileClose 
facDest.FileClose 

outFile.WriteLine("Finished decompressing file.")

outFile.Close