(VBScript) Sign a Byte Array to Create a Detached Signature in a Byte Array

Signs data contained in a byte array to produce a detached signature (also in a byte array). Also shows how to verify the signature.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")

fileBytes = fac.ReadEntireFile("qa_data/pdf/sample.pdf")
If (fac.LastMethodSuccess <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

success = crypt.SetSigningCert(cert)

' We can sign any type of file.
' The result is a detached signature (a signature that does not contain the data being signed).

sigBytes = crypt.SignBytes(fileBytes)
If (crypt.LastMethodSuccess <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

success = fac.WriteEntireFile("qa_output/sample.pdf.p7s",sigBytes)
If (fac.LastMethodSuccess <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' We can verify the detached signature like this
verified = crypt.VerifyBytes(fileBytes,sigBytes)
If (crypt.LastMethodSuccess <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Verified = " & verified)

outFile.Close