(VBScript) Manually Duplicate SetSecretKeyViaPassword

Demonstrates how to duplicate the password string to binary secret key computation of SetSecretKeyViaPassword.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' The password string is transformed to a binary secret key by computing the 
' MD5 digest (of the utf-8 password) to obtain 16 bytes.  
' If the KeyLength is greater than 16 bytes, then the MD5 digest of the Base64 encoding 
' of the utf-8 password is added.  A max of 32 bytes of key material is generated, and 
' this is truncated to the actual KeyLength required.

crypt.CryptAlgorithm = "aes"
crypt.KeyLength = 256

password = "this is my password"
crypt.SetSecretKeyViaPassword password

' Examine the resulting SecretKey in hex:
outFile.WriteLine("Computed Secret Key = " & crypt.GetEncodedKey("hex"))

' Now perform the same computation manually:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")

crypt.HashAlgorithm = "md5"
crypt.Charset = "utf-8"
crypt.EncodingMode = "hex"
success = sb.Append(crypt.HashStringENC(password))

passwordBase64 = crypt.EncodeString(password,"utf-8","base64")
success = sb.Append(crypt.HashStringENC(passwordBase64))

outFile.WriteLine("Manually Computed = " & sb.GetAsString())

' The output is:
' Computed Secret Key = 210D53992DFF432EC1B1A9698AF9DA16C7E90518F90E24828F78EC9E0A413B36
' Manually Computed = 210D53992DFF432EC1B1A9698AF9DA16C7E90518F90E24828F78EC9E0A413B36

outFile.Close