VBScript

Create P7M Using Pre-Installed Windows Certificate

See more Digital Signatures Examples

Demonstrates how to sign a file creating a .p7m file as output. The .p7m contains the signed contents of the original file. It can be verified and restored by calling VerifyP7M.

This example is for Windows only. It automatically searches and locates the desired certificate in the Current User or Local Machine certificate stores. (The certificate must have been pre-installed on the Windows machine, and it must have the private key available. The private key can be located on a USB Authentication Token / Smart Card. If so, then Chilkat *should* automatically use the private key located on the device.)

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

certSubjectCN = "Matt"

set cert = CreateObject("Chilkat.Cert")

' Locate and load the certificate by the common name (subject CN).
' This searches the Windows registry-based Current User and Local Machine
' certificate stores for the certificate.  
success = cert.LoadByCommonName(certSubjectCN)
If (success <> 1) Then
    outFile.WriteLine("Failed to find certificate.")
    WScript.Quit
End If

' Make sure a private key is available.
If (cert.HasPrivateKey() <> 1) Then
    outFile.WriteLine("This certificate does not have a private key located in the Windows protected store, or on a USB device.")
    WScript.Quit
End If

' Specify the cert (and implicitly the private key) to be used for signing.
success = crypt.SetSigningCert(cert)

' -----------------------------------------------------------------------------------------
' Also see Chilkat's online tool to examine a .p7m and generate code to duplicate the .p7m
' -----------------------------------------------------------------------------------------

' We can sign any type of file, creating a .p7m as output:
inFile = "qa_data/pdf/fishing.pdf"
outputFile = "qa_output/fishing.pdf.p7m"
success = crypt.CreateP7M(inFile,outputFile)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Verify and restore the original file:
success = crypt.SetVerifyCert(cert)

inFile = outputFile
outputFile = "qa_output/restored.pdf"

success = crypt.VerifyP7M(inFile,outputFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success!")

outFile.Close