(VBScript) ARC4 Encryption (ARCFOUR)

ARC4 (ARCFOUR) encryption. The Chilkat encryption component supports the ARC4 streaming encryption algorithm.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' Set the encryption algorithm = "arc4"	
crypt.CryptAlgorithm = "arc4"

' KeyLength may range from 1 byte to 256 bytes.
' (i.e. 8 bits to 2048 bits)
' ARC4 key sizes are typically in the range of 
' 40 to 128 bits.
' The KeyLength property is specified in bits:
crypt.KeyLength = 128

' Note: The PaddingScheme and CipherMode properties
' do not apply w/ ARC4.  ARC4 does not encrypt in blocks --
' it is a streaming encryption algorithm. The number of output bytes
' is exactly equal to the number of input bytes.

' EncodingMode specifies the encoding of the output for
' encryption, and the input for decryption.
' It may be "hex", "url", "base64", or "quoted-printable".
crypt.EncodingMode = "hex"

' Note: ARC4 does not utilize initialization vectors.  IV's only
' apply to block encryption algorithms.  

' The secret key must equal the size of the key.
' For 128-bit encryption, the binary secret key is 16 bytes.
keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

' Encrypt a string...
' The output length is exactly equal to the input.  In this
' example, the input string is 44 chars (ANSI bytes) so the
' output is 44 bytes -- and when hex encoded results in an
' 88-char string (2 chars per byte for the hex encoding).
encStr = crypt.EncryptStringENC("The quick brown fox jumps over the lazy dog.")
outFile.WriteLine(encStr)

' Now decrypt:
decStr = crypt.DecryptStringENC(encStr)
outFile.WriteLine(decStr)

outFile.Close