(VBScript) Convert PDF to pdf.p7s (Digitally Signed)

Demonstrates how to convert a PDF into a .p7s file that contains the PDF within a PKCS7 signature (the .p7s format).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Tell the crypt component to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' The CadesEnabled property applies to all methods that create PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

crypt.HashAlgorithm = "sha256"

' We can sign any type of file, creating a .p7s as output.
' The .p7s contains the signature and also embeds the data of the file that is signed.
inFile = "qa_data/pdf/sample.pdf"
p7sFile = "qa_output/sample.pdf.p7s"

' -----------------------------------------------------------------------------------------
' Also see Chilkat's online tool to examine a .p7m and generate code to duplicate the .p7m
' -----------------------------------------------------------------------------------------

' Create the CAdES-BES attached signature, which contains the original data.
' Note: Chilkat's function naming is not accurate.  CreateP7M creates a PKCS7 signature where the signed file
' is contained within the signature.  CreateP7S creates a detached PKCS7 signature where the signed file
' is NOT contained within the signature.  We want the data to be contained in the signature, therefore
' we call CreateP7M even though we are naming our output file .p7s.
success = crypt.CreateP7M(inFile,p7sFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Verify the .p7s file and extract the original file from the .p7s. 
extractedToFilePath = "qa_output/sample.pdf"
success = crypt.VerifyP7M(p7sFile,extractedToFilePath)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success!")

outFile.Close