VBScript

Convert Cert + Key to PEM and PFX

See more Certificates Examples

This example is based on the following question from a Chilkat customer:

We receive 2 files :

    MyCertificate.p7b
    MyCertificate-privatekey.pkey

We have to transform these certificate like this:

First convert it to PEM like this:

openssl pkcs7 -in MyCertificate.p7b -inform DER -out MyCertificate.pem -print_certs

Now we get MyCertificate.pem

Last step, we need to convert it to pfx file:

openssl pkcs12 -export -inkey moncertificat-privatekey.pkey  -in  moncertificat.pem -out moncertificat.pfx

Is there a way to make all these steps with Chilkat ?

I will be nice to include this directly in our software instead of askig the user to do it manualy.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set cert = CreateObject("Chilkat.Cert")
set privKey = CreateObject("Chilkat.PrivateKey")

' Load any type of certificate (.cer, .p7b, .pem, etc.) by calling LoadFromFile.
success = cert.LoadFromFile("qa_data/certs/sample_cert_a.cer")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Load the private key.
' (The various privKey methods that load from a file will automatically detect
' the format.  It doesn't actually matter if you try to load a non-PKCS8 format private key
' by calling LoadPkcs8EncryptedFile -- internally Chilkat will detect the format and will load
' based on what it finds.)
success = privKey.LoadPkcs8EncryptedFile("qa_data/certs/sample_key_a.pkcs8","password")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' Write the cert as PEM.
success = cert.ExportCertPemFile("qa_output/cert.pem")

' Or get the PEM string directly...
outFile.WriteLine(cert.ExportCertPem())

' Associate the private key with the cert object.
success = cert.SetPrivateKey(privKey)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Write the cert + private key to a .pfx file.
success = cert.ExportToPfxFile("qa_data/myPfx.pfx","password",1)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close