(VBScript) Compress Text Feed to Binary

This example receives incoming text data in chunks, compresses as a stream, and accumulates the compressed binary data.

The purpose is to demonstrate the BeginCompressString, MoreCompressString, and EndCompressString methods.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set compressedData = CreateObject("Chilkat.BinData")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Compression")
set compress = CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"
compress.Charset = "utf-8"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbIndex = CreateObject("Chilkat.StringBuilder")

For i = 0 To 24
    ' Note: It is possible (and normal) for a BeginCompress* or MoreCompress* method to return
    ' an empty string (or 0 bytes).  When this happens, the input data is not lost.  It will be flushed
    ' in a subsequent call.
    sbIndex.Clear 
    success = sbIndex.AppendInt(i)
    If (i = 0) Then
        compressedBytes = compress.BeginCompressString(sbIndex.GetAsString())
    Else
        compressedBytes = compress.MoreCompressString(sbIndex.GetAsString())
    End If

    success = compressedData.AppendBinary(compressedBytes)
    compressedBytes = compress.MoreCompressString(": This is a line of data to be compressed..." & vbCrLf)
    success = compressedData.AppendBinary(compressedBytes)
Next

' Flush any remaining output.
compressedBytes = compress.EndCompressString()
success = compressedData.AppendBinary(compressedBytes)

' Show the compressed data in hex format:
outFile.WriteLine("The hex encoded compressed text:")
outFile.WriteLine(compressedData.GetEncoded("hex"))

' Now decompress in one call:
compressedBytes = compressedData.GetBinary()
originalText = compress.DecompressString(compressedBytes)
outFile.WriteLine(originalText)

outFile.Close