(VBScript) Compress String Feed to Base64

This example receives incoming text data in chunks, compresses as a stream, and accumulates the compressed data in base64.

The purpose is to demonstrate the BeginCompressStringENC, MoreCompressStringENC, and EndCompressStringENC methods.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbCompressedBase64 = CreateObject("Chilkat.StringBuilder")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Compression")
set compress = CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"
compress.Charset = "utf-8"
compress.EncodingMode = "base64"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbIndex = CreateObject("Chilkat.StringBuilder")

For i = 0 To 24
    ' Note: It is possible (and normal) for a BeginCompress* or MoreCompress* method to return
    ' an empty string (or 0 bytes).  When this happens, the input data is not lost.  It will be flushed
    ' in a subsequent call.
    sbIndex.Clear 
    success = sbIndex.AppendInt(i)
    If (i = 0) Then
        success = sbCompressedBase64.Append(compress.BeginCompressStringENC(sbIndex.GetAsString()))
    Else
        success = sbCompressedBase64.Append(compress.MoreCompressStringENC(sbIndex.GetAsString()))
    End If

    success = sbCompressedBase64.Append(compress.MoreCompressStringENC(": This is a line of data to be compressed..." & vbCrLf))
Next

' Flush any remaining output.
success = sbCompressedBase64.Append(compress.EndCompressStringENC())

outFile.WriteLine("The base64 encoded compressed text:")
outFile.WriteLine(sbCompressedBase64.GetAsString())

' Now decompress in one call:
originalText = compress.DecompressStringENC(sbCompressedBase64.GetAsString())
outFile.WriteLine(originalText)

outFile.Close