(VBScript) Get Certificate User Principal Name (UPN)

See more Certificates Examples

Demonstrates how to get a certificate's UPN from the SAN (Subject Alternative Name). Most certificates do not have a UPN. This example only applies to those certificates that have a User Principal Name.

Note: This example requires Chilkat v9.5.0.90 or greater due to fixes made in getting the UPN from the SAN.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")

success = cert.LoadFromFile("qa_data/certs/sample.cer")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(cert.SubjectAlternativeName)
outFile.WriteLine(xml.GetXml())

' A certificate with a User Principal Name in the SAN might have this:

' <SubjectAltName>
'     <rfc822Name>joe@example.com</rfc822Name>
'     <name type="oid" oid="1.3.6.1.4.1.311.20.2.3">joe@example.com</name>
' </SubjectAltName>

' The OID 1.3.6.1.4.1.311.20.2.3 is for the User Principal Name.
upn = xml.ChilkatPath("/A/name,oid,1.3.6.1.4.1.311.20.2.3|*")
If (xml.LastMethodSuccess = 0) Then
    outFile.WriteLine("No user principle name.")
Else
    outFile.WriteLine("User Principle Name = " & upn)
End If


outFile.Close