(VBScript) Load Certificate from PFX (PKCS#12)

Loads a digital certificate (and private key, if available) from a PFX file.(also known as PKCS#12)

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")

' Load from the PFX file
pfxFilename = "/Users/chilkat/testData/pfx/chilkat_ssl_pwd_is_test.pfx"
pfxPassword = "test"

' A PFX typically contains certificates in the chain of authentication.
' The Chilkat cert object will choose the certificate w/
' private key farthest from the root authority cert.
' To access all the certificates in a PFX, use the 
' Chilkat certificate store object instead.
success = cert.LoadPfxFile(pfxFilename,pfxPassword)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Get some information about the digital certificate, 
' then get the private key...

' DN = "Distinguished Name"
outFile.WriteLine("SubjectDN:" & cert.SubjectDN)

outFile.WriteLine("Common Name:" & cert.SubjectCN)
outFile.WriteLine("Issuer Common Name:" & cert.IssuerCN)

outFile.WriteLine("Serial Number:" & cert.SerialNumber)

' Now for the private key...

' privKey is a Chilkat.PrivateKey
Set privKey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' The private key object may be used in any Chilkat methods
' (in other objects/classes) that expect a private key argument.

' In this case, save the private key to a PKCS8 Encrypted PEM format file:
pemPassword = "secret"
pemPath = "/Users/chilkat/testData/pem/chilkat_privKey.pem"
success = privKey.SavePkcs8EncryptedPemFile(pemPassword,pemPath)
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)

    WScript.Quit
End If

outFile.WriteLine("Private key saved to PKCS8 Encrypted PEM...")

outFile.Close