(VBScript) Get Certificate Valid To/From Dates

Demonstrates how to get the certificate "valid from" and "valid to" dates.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")

success = cert.LoadFromFile("qa_data/certs/testCert.cer")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Get the certificate valid-from date/time
' ckdt is a Chilkat.CkDateTime
Set ckdt = cert.GetValidFromDt()
' Get the local timestamp string.
outFile.WriteLine("Valid from: " & ckdt.GetAsTimestamp(1))
' Valid from: 2017-03-17T19:00:00-05:00

' Now get the date/time as another object where we can get the individual numeric date parts.
' dt is a Chilkat.DtObj
Set dt = ckdt.GetDtObj(1)
outFile.WriteLine(dt.Day & "/" & dt.Month & "/" & dt.Year & "  " & dt.Hour & ":" & dt.Minute)

' Get the certificate valid-to date/time
' ckdt is a Chilkat.CkDateTime
Set ckdt = cert.GetValidToDt()
outFile.WriteLine("Valid to: " & ckdt.GetAsTimestamp(1))
' Valid to: 2020-03-18T18:59:59-05:00
' dt is a Chilkat.DtObj
Set dt = ckdt.GetDtObj(1)
outFile.WriteLine(dt.Day & "/" & dt.Month & "/" & dt.Year & "  " & dt.Hour & ":" & dt.Minute)


outFile.Close