(VBScript) Get a Certificate's Key Size

Demonstrates how to get the RSA key size of a certificate (for example, 1024-bit, 2048-bit, etc.)

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For this example, I have a certificate in raw base64 format (not PEM),
' that looks like this:  "MIIGkDCCBHigAwIBAgIUMDA ... s/iqLsLA=="
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbCertBase64 = CreateObject("Chilkat.StringBuilder")
success = sbCertBase64.LoadFile("qa_data/certs/base64Cert.txt","utf-8")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromBase64(sbCertBase64.GetAsString())
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Get the public key.
' pubKey is a Chilkat.PublicKey
Set pubKey = cert.ExportPublicKey()
If (cert.LastMethodSuccess <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' In Chilkat version v9.5.0.67, the KeySize property was added.
numBits = pubKey.KeySize
outFile.WriteLine("Number of bits = " & numBits)

' If using an older version of Chilkat, the key size can be obtained like this:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(pubKey.GetXml())

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set binDat = CreateObject("Chilkat.BinData")
success = binDat.AppendEncoded(xml.GetChildContent("Modulus"),"base64")

numBits = 8 * binDat.NumBytes
outFile.WriteLine("Number of bits = " & numBits)


outFile.Close