(VBScript) CAdES BES Detached Signature

Demonstrates how to create a CAdES BES detached signature file (.p7s).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' Use a digital certificate and private key from a PFX file (.pfx or .p12).
pfxPath = "/Users/chilkat/testData/pfx/acme.pfx"
pfxPassword = "test123"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Tell the crypt component to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' The CadesEnabled property applies to all methods that create PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

' We can sign any type of file, creating a .p7s as output:
inFile = "/Users/chilkat/testData/pdf/sample.pdf"
sigFile = "/Users/chilkat/testData/p7s/sample.p7s"

' Create the detached CAdES-BES signature:
success = crypt.CreateP7S(inFile,sigFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

success = crypt.VerifyP7S(inFile,sigFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success!")

outFile.Close