VBScript

Read Bitfinex WebSocket Ticker Channel

See more WebSocket Examples

Subscribes to the public Bitfinex websocket ticker channel and receives ticker updates. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ws = CreateObject("Chilkat.WebSocket")

' For brevity, this example does not check for errors when etablishing the WebSocket connection.
' See Establish WebSocket Connection for more complete sample code for making the connection.

set rest = CreateObject("Chilkat.Rest")

' Connect to api.bitfinex.com
success = rest.Connect("api.bitfinex.com",443,1,0)
success = ws.UseConnection(rest)
success = ws.AddClientHeaders()

responseBody = rest.FullRequestNoBody("GET","/ws")
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    outFile.WriteLine(ws.LastErrorText)
    outFile.WriteLine(responseBody)
    outFile.WriteLine(rest.ResponseHeader)
    WScript.Quit
End If

' After connecting, the bitfinex websocket server will send
' an info message that contains the actual version of the websocket stream.
' Receive that message..
success = ws.ReadFrame()
If (success <> 1) Then
    outFile.WriteLine("Failed to receive a frame")
    outFile.WriteLine("ReadFrame fail reason = " & ws.ReadFrameFailReason)
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

' We should get this:
' {"event":"info","version":1.1,"platform":{"status":1}}
outFile.WriteLine(ws.GetFrameData())

' Subscribe to the public ticker feed.
' See https://docs.bitfinex.com/docs for more information.
set json = CreateObject("Chilkat.JsonObject")
success = json.AppendString("event","subscribe")
success = json.AppendString("channel","ticker")
success = json.AppendString("pair","BTCUSD")

finalFrame = 1
success = ws.SendFrame(json.Emit(),finalFrame)

' Read the response.
success = ws.ReadFrame()
If (success <> 1) Then
    outFile.WriteLine("Failed to receive a frame")
    outFile.WriteLine("ReadFrame fail reason = " & ws.ReadFrameFailReason)
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

' Examine the response
' We should get this:
' {"event":"subscribed","channel":"ticker","chanId":2751,"pair":"BTCUSD"}
outFile.WriteLine(ws.GetFrameData())

' Begin reading the ticker feed.
' We'll just read the 1st 5 updates and then exit..
receivedFinalFrame = 0
numUpdatesReceived = 0
Do While numUpdatesReceived < 5

    success = ws.ReadFrame()
    If (success <> 1) Then
        outFile.WriteLine("Failed to receive a frame")
        outFile.WriteLine("ReadFrame fail reason = " & ws.ReadFrameFailReason)
        outFile.WriteLine(ws.LastErrorText)
        WScript.Quit
    End If

    ' The responses we desire are in Text frames, where the opcode = 1.
    If (ws.FrameOpcodeInt = 1) Then
        receivedText = ws.GetFrameData()
        outFile.WriteLine(receivedText)
        ' Should receive a line of text such as this:
        ' [2751,7349,36.34269559,7349.1,41.01777063,-116.2,-0.0156,7349.1,22188.26055319,7560,7270.5]
        numUpdatesReceived = numUpdatesReceived + 1
    End If

Loop

' Close the websocket connection.
success = ws.SendClose(1,1000,"Closing this websocket.")
If (success <> 1) Then
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

' Read the Close response.
success = ws.ReadFrame()
If (success <> 1) Then
    outFile.WriteLine("ReadFrame fail reason = " & ws.ReadFrameFailReason)
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close