(VBScript) Azure Storage: Upload Binary Data to Block Blob

Sample code to upload binary bytes to a block blob in Azure Cloud Storage. This creates the block blob, or replaces an existing block blob.

Note: The maximum size of a block blob created by uploading in a single step is 64MB. For larger files, the upload must be broken up into blocks. There is another Chilkat example for that..

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Upload binary bytes to a block blob.
' This creates a new block blob or replaces an existing one in its entirety.
' See also: https://msdn.microsoft.com/en-us/library/azure/dd179451.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: Content-Length, x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' IMPORTANT: Make sure to set the x-ms-blob-type header:
success = rest.AddHeader("x-ms-blob-type","BlockBlob")

' For this example, we'll just load a JPG file into memory..

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
binaryData = fac.ReadEntireFile("qa_data/jpg/starfish.jpg")

' Note: The maximum size of a block blob created by uploading in a single step is 64MB.  
' For larger files, the upload must be broken up into blocks.  There is another Chilkat example for that..
responseStr = rest.FullRequestBinary("PUT","/mycontainer/starfish.jpg",binaryData)
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 201 response status code,
' with no response body.

If (rest.ResponseStatusCode <> 201) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close