VBScript

Upload using Azure Storage Account Shared Access Signature (SAS) Authorization

See more Azure Cloud Storage Examples

Sample code to upload binary bytes to a block blob in Azure Cloud Storage using an Azure Storage Account Shared Access Signature (SAS) Authorization. This creates a block blob, or replaces an existing block blob.

Note: The maximum size of a block blob created by uploading in a single step is 64MB. For larger files, the upload must be broken up into blocks. There is another Chilkat example for that..

Note: This example requires Chilkat v9.5.0.65 or later.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Note: This example requires Chilkat v9.5.0.65 or greater.

' Azure Blob Service Example: Upload binary bytes to a block blob.
' This uses a Shared Access Signature (SAS) for Authorization.
' This creates a new block blob or replaces an existing one in its entirety.
' See also: https://msdn.microsoft.com/en-us/library/azure/dd179451.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Note: The application does not need to explicitly set the following
' headers: Content-Length, x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' Let's load a previously computed Azure Storage Account SAS token and use it.
' See How to Create an Azure Storage Account Shared Access Signature
set sbToken = CreateObject("Chilkat.StringBuilder")
success = sbToken.LoadFile("qa_data/tokens/azureStorageAccountSas.txt","utf-8")
If (success <> 1) Then
    outFile.WriteLine("Failed to load SAS token.")
    WScript.Quit
End If

' Add the Shared Access Signature query params for authorization.
success = rest.AddQueryParams(sbToken.GetAsString())

' IMPORTANT: Make sure to set the x-ms-blob-type header:
success = rest.AddHeader("x-ms-blob-type","BlockBlob")

' IMPORTANT: Make sure to add the x-ms-date header.
' When the header name is "x-ms-date", Chilkat will recognize the keyword "NOW" 
' and will substitute the current system date/time formatted as required by Microsoft.
success = rest.AddHeader("x-ms-date","NOW")

' For this example, we'll just load a JPG file into memory..
set binData = CreateObject("Chilkat.BinData")
success = binData.LoadFile("qa_data/jpg/starfish.jpg")
If (success <> 1) Then
    outFile.WriteLine("Failed to load JPG file.")
    WScript.Quit
End If

' Note: The maximum size of a block blob created by uploading in a single step is 64MB.  
' For larger files, the upload must be broken up into blocks.  There is another Chilkat example for that..
set sbResponse = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestBd("PUT","/mycontainer/starfish.jpg",binData,sbResponse)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 201 response status code,
' with no response body.
If (rest.ResponseStatusCode <> 201) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & sbResponse.GetAsString())
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close