(VBScript) Set Container ACL

Azure Storage Blob Service REST API: Sample code to set the permissions of a container.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Set Container ACL
' See also: https://msdn.microsoft.com/en-us/library/azure/dd179391.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' The XML body of the request will look like this:

' <?xml version="1.0" encoding="utf-8"?>
' <SignedIdentifiers>
'   <SignedIdentifier> 
'     <Id>unique-character-value-of-up-to-64-chars</Id>
'     <AccessPolicy>
'       <Start>start-time</Start>
'       <Expiry>expiry-time</Expiry>
'       <Permission>abbreviated-permission-list</Permission>
'     </AccessPolicy>
'   </SignedIdentifier>
' </SignedIdentifiers>

' Generate a random 32-character string.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Prng")
set prng = CreateObject("Chilkat.Prng")
randomId = prng.RandomString(32,1,1,1)

' Get the current system date/time in ISO 8061 format
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dt = CreateObject("Chilkat.CkDateTime")
success = dt.SetFromCurrentSystemTime()
bLocal = 0
' Get the current date/time in ISO 8061 UTC format.
curDtStr = dt.GetAsTimestamp(bLocal)
' The expire time will be 365 days in the future.
success = dt.AddDays(365)
expireDtStr = dt.GetAsTimestamp(bLocal)

' Build the request:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "SignedIdentifiers"
' xSignedId is a Chilkat.Xml
Set xSignedId = xml.NewChild("SignedIdentifier","")
xSignedId.NewChild2 "Id",randomId
' xAccessPolicy is a Chilkat.Xml
Set xAccessPolicy = xSignedId.NewChild("AccessPolicy","")
xAccessPolicy.NewChild2 "Start",curDtStr
xAccessPolicy.NewChild2 "Expiry",expireDtStr
xAccessPolicy.NewChild2 "Permission","rwd"

' Show the XML..
outFile.WriteLine(xml.GetXml())

' The expected response is a 200 response status code with no response body.
responseStr = rest.FullRequestString("PUT","/mycontainer?restype=container&comp=acl",xml.GetXml())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200 response status code,
' with no response body.

If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close