(VBScript) Azure Storage: Set Blob Service Properties

Azure Storage Blob Service REST API: Sample code to set a blob's service properties.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Set Blob Service Properties
' See also: https://msdn.microsoft.com/en-us/library/azure/hh452235.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' This example will set logging properties.  The XML body of the request
' will look like this:

' <?xml version="1.0" encoding="utf-8"?>
' <StorageServiceProperties>
'     <Logging>
'         <Version>version-number</Version>
'         <Delete>true|false</Delete>
'         <Read>true|false</Read>
'         <Write>true|false</Write>
'         <RetentionPolicy>
'             <Enabled>true|false</Enabled>
'             <Days>number-of-days</Days>
'         </RetentionPolicy>
'     </Logging>

' Build the request:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "StorageServiceProperties"
' xLogging is a Chilkat.Xml
Set xLogging = xml.NewChild("Logging","")
xLogging.NewChild2 "Version","1.0"
xLogging.NewChild2 "Delete","true"
xLogging.NewChild2 "Read","true"
xLogging.NewChild2 "Write","true"
' xRetension is a Chilkat.Xml
Set xRetension = xLogging.NewChild("RetentionPolicy","")
xRetension.NewChild2 "Enabled","true"
xRetension.NewChild2 "Days","7"

' The expected response is a 202 response status code with no response body.
responseStr = rest.FullRequestString("PUT","/?restype=service&comp=properties",xml.GetXml())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 202 response code,
' with no response body.
If (rest.ResponseStatusCode <> 202) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Success: Blob service properties updated!")

outFile.Close