(VBScript) Azure Service Bus - Create Subscription

Creates an Azure Service Bus Subscription.

Note: This example requires Chilkat v9.5.0.65 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: Requires Chilkat v9.5.0.65 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Make the initial connection.
' A single REST object, once connected, can be used for many Azure Service Bus REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
bAutoReconnect = 1
success = rest.Connect("<yournamespace>.servicebus.windows.net",443,1,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Let's load a previously computed SAS token and use it.
' See Azure Shared Access Signature for an example to genenerate an Azure SAS token.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbToken = CreateObject("Chilkat.StringBuilder")
success = sbToken.LoadFile("qa_data/tokens/serviceBusSas.txt","utf-8")

' Tell the REST object to use the Azure Shared Access Signature for authorization.
success = sbToken.Prepend("SharedAccessSignature ")
success = rest.AddHeader("Authorization",sbToken.GetAsString())

' ----------------------------------------------------------------------------------------------

' Create a new subscription named "feedings";
topicName = "gilaMonster"
subscriptionName = "feedings"

' Create the XML body of the PUT request.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "entry"
success = xml.AddAttribute("xmlns","http://www.w3.org/2005/Atom")
success = xml.UpdateAttrAt("title",1,"type","text")
xml.UpdateChildContent "title",subscriptionName
success = xml.UpdateAttrAt("content",1,"type","application/xml")
success = xml.UpdateAttrAt("content|SubscriptionDescription",1,"xmlns:i","http://www.w3.org/2001/XMLSchema-instance")
success = xml.UpdateAttrAt("content|SubscriptionDescription",1,"xmlns","http://schemas.microsoft.com/netservices/2010/10/servicebus/connect")
xml.EmitXmlDecl = 0
outFile.WriteLine(xml.GetXml())

' The XML created by the above code:

' 	<entry xmlns="http://www.w3.org/2005/Atom">
' 	    <title type="text">feedings</title>
' 	    <content type="application/xml">
' 	        <SubscriptionDescription xmlns:i="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://schemas.microsoft.com/netservices/2010/10/servicebus/connect" />
' 	    </content>
' 	</entry>

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbRequestBody = CreateObject("Chilkat.StringBuilder")
success = xml.GetXmlSb(sbRequestBody)

' The path should be set to the to-be-created queue name.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/")
success = sbPath.Append(topicName)
success = sbPath.Append("/Subscriptions/")
success = sbPath.Append(subscriptionName)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponseBody = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestSb("PUT",sbPath.GetAsString(),sbRequestBody,sbResponseBody)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response Status Code = " & rest.ResponseStatusCode)

' Check for a success response.
If (rest.ResponseStatusCode <> 201) Then
    outFile.WriteLine(rest.LastRequestStartLine)
    outFile.WriteLine(rest.LastRequestHeader)
    outFile.WriteLine(sbResponseBody.GetAsString())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' The response is XML.  (See a sample response below..)
success = xml.LoadSb(sbResponseBody,1)
outFile.WriteLine(xml.GetXml())

outFile.WriteLine("Success.")

' -----------------------------------------------
' A sample successful XML response:

' 	<entry xmlns="http://www.w3.org/2005/Atom">
' 	    <id>https://chilkat.servicebus.windows.net/gilaMonster/Subscriptions/feedings</id>
' 	    <title type="text">feedings</title>
' 	    <published>2016-12-07T16:02:24Z</published>
' 	    <updated>2016-12-07T16:02:24Z</updated>
' 	    <link rel="self" href="https://chilkat.servicebus.windows.net/gilaMonster/Subscriptions/feedings" />
' 	    <content type="application/xml">
' 	        <SubscriptionDescription xmlns="http://schemas.microsoft.com/netservices/2010/10/servicebus/connect" xmlns:i="http://www.w3.org/2001/XMLSchema-instance">
' 	            <LockDuration>PT1M</LockDuration>
' 	            <RequiresSession>false</RequiresSession>
' 	            <DefaultMessageTimeToLive>P10675199DT2H48M5.4775807S</DefaultMessageTimeToLive>
' 	            <DeadLetteringOnMessageExpiration>false</DeadLetteringOnMessageExpiration>
' 	            <DeadLetteringOnFilterEvaluationExceptions>true</DeadLetteringOnFilterEvaluationExceptions>
' 	            <MessageCount>0</MessageCount>
' 	            <MaxDeliveryCount>10</MaxDeliveryCount>
' 	            <EnableBatchedOperations>true</EnableBatchedOperations>
' 	        </SubscriptionDescription>
' 	    </content>
' 	</entry>

outFile.Close