(VBScript) Upload File in Blocks (with Content-MD5 header) and Commit the Block List

Demonstrates how to upload a file in blocks and then commit the block list. This example includes a Content-MD5 header for each block.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Upload a file in blocks, and then commit the block list.
' See also: https://msdn.microsoft.com/en-us/library/azure/dd135726.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: Content-Length, x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' As the blocks are uploaded, we'll keep an XML block list for the subsequent commit..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "BlockList"

' Any type of file can be uploaded in this way.  It can a text file, binary file, anything...
' This example will upload an XML file that is approximately 275K in size.  It can be downloaded
' at http://www.chilkatsoft.com/hamlet.xml
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
success = fac.OpenForRead("qa_data/xml/hamlet.xml")
' Assuming success for the example..

' We'll upload in 16K blocks (normally a program would upload in larger block sizes than this,
' but this is just an example...)
blockSize = 16384

' How many 16K blocks?  (Including 1 for the last partial block)
numBlocks = fac.GetNumBlocks(blockSize)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "md5"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponseBody = CreateObject("Chilkat.StringBuilder")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set uriPath = CreateObject("Chilkat.StringBuilder")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set dataBlock = CreateObject("Chilkat.BinData")

i = 0
Do While i < numBlocks

    success = dataBlock.Clear()
    success = fac.ReadBlockBd(i,blockSize,dataBlock)
    If (success = 0) Then
        outFile.WriteLine(fac.LastErrorText)
        WScript.Quit
    End If

    ' Generate a base64 block ID.  
    ' (Chilkat provides a helper method named GenBlockId to make this easy)
    ' A pre-base64 encoded block ID length of 4 is sufficient in this case because
    ' this file certainly won't have more than 99,999 blocks..
    blockId = fac.GenBlockId(i,4,"base64")

    ' Add this blockId to the list of blocks to be committed.
    xml.NewChild2 "Latest",blockId

    ' Build the URI path
    uriPath.Clear 
    success = uriPath.Append("/mycontainer/hamlet.xml?comp=block&blockId=")
    success = uriPath.Append(blockId)

    contentMd5 = crypt.HashBdENC(dataBlock)
    success = rest.AddHeader("Content-MD5",contentMd5)

    ' Upload this block..
    sbResponseBody.Clear 
    success = rest.FullRequestBd("PUT",uriPath.GetAsString(),dataBlock,sbResponseBody)
    If (success = 0) Then
        outFile.WriteLine(rest.LastErrorText)
        WScript.Quit
    End If

    ' Verify that we received a 201 status code.
    If (rest.ResponseStatusCode <> 201) Then
        ' Examine the request/response to see what happened.
        outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
        outFile.WriteLine("response status text = " & rest.ResponseStatusText)
        outFile.WriteLine("response header: " & rest.ResponseHeader)
        outFile.WriteLine("response body (if any): " & sbResponseBody.GetAsString())
        outFile.WriteLine("---")
        outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
        outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
        WScript.Quit
    End If

    i = i + 1
Loop

fac.FileClose 

' Now commit the blocks.
' Let's have a look at the XML that will commit the blocks:
xmlStr = xml.GetXml()
outFile.WriteLine(xmlStr)

' The XML will look like this:

' <?xml version="1.0" encoding="utf-8" ?>
' <BlockList>
'     <Latest>MDAwMA==</Latest>
'     <Latest>MDAwMQ==</Latest>
'     <Latest>MDAwMg==</Latest>
'     <Latest>MDAwMw==</Latest>
'     <Latest>MDAwNA==</Latest>
'     <Latest>MDAwNQ==</Latest>
'     <Latest>MDAwNg==</Latest>
'     <Latest>MDAwNw==</Latest>
'     <Latest>MDAwOA==</Latest>
'     <Latest>MDAwOQ==</Latest>
'     <Latest>MDAxMA==</Latest>
'     <Latest>MDAxMQ==</Latest>
'     <Latest>MDAxMg==</Latest>
'     <Latest>MDAxMw==</Latest>
'     <Latest>MDAxNA==</Latest>
'     <Latest>MDAxNQ==</Latest>
'     <Latest>MDAxNg==</Latest>
'     <Latest>MDAxNw==</Latest>
' </BlockList>

' --------------------------------------------------------------------------
' IMPORTANT: Remove the Content-MD5 header previously set in the loop above.
' --------------------------------------------------------------------------
success = rest.RemoveHeader("Content-MD5")

' Send the PUT Block List...
responseStr = rest.FullRequestString("PUT","/mycontainer/hamlet.xml?comp=blocklist",xmlStr)
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 201 response status code,
' with no response body.

If (rest.ResponseStatusCode <> 201) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close