(VBScript) Azure Storage: List Blobs

Azure Storage Blob Service REST API: Sample code to fetch the list of blobs in the specified container.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: List the blobs in a specified container.
' See also: https://msdn.microsoft.com/en-us/library/azure/dd135734.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' The expected success response is a 200 response status code with an XML response body.
' In this example, we are listing the blobs in the container named "mycontainer".
responseStr = rest.FullRequestNoBody("GET","/mycontainer?restype=container&comp=list")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200 response status code,
' with an XML response body.

If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' Load the XML response for parsing.
' An example of the response XML is shown below.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseStr)

outFile.WriteLine(xml.GetXml())

' Let's iterate over the blobs...

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set lastMod = CreateObject("Chilkat.CkDateTime")

numBlobs = xml.NumChildrenAt("Blobs")
i = 0
Do While i < numBlobs
    outFile.WriteLine("---- Blob " & i & " ----")
    xml.I = i
    outFile.WriteLine("Name: " & xml.GetChildContent("Blobs|Blob[i]|Name"))
    outFile.WriteLine("Content-Length: " & xml.GetChildContent("Blobs|Blob[i]|Properties|Content-Length"))
    outFile.WriteLine("Content-Type: " & xml.GetChildContent("Blobs|Blob[i]|Properties|Content-Type"))
    outFile.WriteLine("Content-MD5: " & xml.GetChildContent("Blobs|Blob[i]|Properties|Content-MD5"))
    outFile.WriteLine("BlobType: " & xml.GetChildContent("Blobs|Blob[i]|Properties|BlobType"))
    outFile.WriteLine("LeaseStatus: " & xml.GetChildContent("Blobs|Blob[i]|Properties|LeaseStatus"))
    success = lastMod.SetFromRfc822(xml.GetChildContent("Blobs|Blob[i]|Properties|Last-Modified"))
    ' dt is a Chilkat.DtObj
    Set dt = lastMod.GetDtObj(1)
    outFile.WriteLine("Last-Modified YMD: " & dt.Year & "," & dt.Month & "," & dt.Day)

    i = i + 1
Loop

outFile.WriteLine("-------------------------")

' Use the ChilkatPath method to get information for a specific blob:

' For example, let's say we want the Last-Modified date/time for
' the blob named "helloWorld.txt"
lastModStr = xml.ChilkatPath("/C/Name,helloWorld.txt|..|Properties|Last-Modified|*")
outFile.WriteLine("helloWorld.txt Last-Modified: " & lastModStr)

outFile.WriteLine("Success.")

' <?xml version="1.0" encoding="utf-8" ?>
' <EnumerationResults ServiceEndpoint="https://chilkat.blob.core.windows.net/" ContainerName="test">
'     <Blobs>
'         <Blob>
'             <Name>hamletC.xml</Name>
'             <Properties>
'                 <Last-Modified>Mon, 02 May 2016 23:50:30 GMT</Last-Modified>
'                 <Etag>0x8D372E48B6D323A</Etag>
'                 <Content-Length>279658</Content-Length>
'                 <Content-Type>application/octet-stream</Content-Type>
'                 <Content-Encoding />
'                 <Content-Language />
'                 <Content-MD5>4E6prI9haw81xadSLeEj3Q==</Content-MD5>
'                 <Cache-Control />
'                 <Content-Disposition>attachment; filename="hamletC.xml"</Content-Disposition>
'                 <BlobType>BlockBlob</BlobType>
'                 <LeaseStatus>unlocked</LeaseStatus>
'                 <LeaseState>available</LeaseState>
'             </Properties>
'         </Blob>
'         <Blob>
'             <Name>helloWorld.txt</Name>
'             <Properties>
'                 <Last-Modified>Mon, 02 May 2016 15:21:55 GMT</Last-Modified>
'                 <Etag>0x8D3729D7EE38299</Etag>
'                 <Content-Length>12</Content-Length>
'                 <Content-Type>application/octet-stream</Content-Type>
'                 <Content-Encoding />
'                 <Content-Language />
'                 <Content-MD5>7Qdih1MuhjZehB6Sv8UNjA==</Content-MD5>
'                 <Cache-Control />
'                 <Content-Disposition>attachment; filename="helloWorld.txt"</Content-Disposition>
'                 <BlobType>BlockBlob</BlobType>
'                 <LeaseStatus>unlocked</LeaseStatus>
'                 <LeaseState>available</LeaseState>
'             </Properties>
'         </Blob>
'         <Blob>
'             <Name>thisIsATest.txt</Name>
'             <Properties>
'                 <Last-Modified>Tue, 03 May 2016 00:22:13 GMT</Last-Modified>
'                 <Etag>0x8D372E8F9B2A62E</Etag>
'                 <Content-Length>1600</Content-Length>
'                 <Content-Type>application/octet-stream</Content-Type>
'                 <Content-Encoding />
'                 <Content-Language />
'                 <Content-MD5>FhgUXYfePg2ItsraPmz0Xg==</Content-MD5>
'                 <Cache-Control />
'                 <Content-Disposition>attachment; filename="thisIsATest.txt"</Content-Disposition>
'                 <BlobType>BlockBlob</BlobType>
'                 <LeaseStatus>unlocked</LeaseStatus>
'                 <LeaseState>available</LeaseState>
'             </Properties>
'         </Blob>
'     </Blobs>
'     <NextMarker />
' </EnumerationResults>
' 

outFile.Close