(VBScript) Azure Storage: Lease Container

Azure Storage Blob Service REST API: Sample code to establishes a lock on a container for delete operations. The lock duration can be 15 to 60 seconds, or can be infinite.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Lease Container
' See also: https://msdn.microsoft.com/en-us/library/azure/jj159103.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' The lease ID needs to be a GUID.  (UUID and GUID are synonymous)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
guid = crypt.GenerateUuid()
outFile.WriteLine("Lease ID: " & guid)
success = rest.AddHeader("x-ms-lease-id",guid)

' The action can be "acquire", "renew", "change", "release", or "break".
' See https://msdn.microsoft.com/en-us/library/azure/jj159103.aspx
success = rest.AddHeader("x-ms-lease-action","acquire")

' The lease duration..
success = rest.AddHeader("x-ms-lease-duration","15")

' In this example, we are acquiring a lease for the container named "mycontainer".
responseStr = rest.FullRequestNoBody("PUT","/mycontainer?restype=container&comp=lease")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200, 201, or 202 response status code,
' with no response body.

' The status code depends on the operation:
'    Acquire: A successful operation returns status code 201 (Created).
'    Renew: A successful operation returns status code 200 (OK).
'    Change: A successful operation returns status code 200 (OK).
'    Release: A successful operation returns status code 200 (OK).
'    Break: A successful operation returns status code 202 (Accepted).

If ((rest.ResponseStatusCode < 200) Or (rest.ResponseStatusCode > 202)) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Success: Lease acquired.")

outFile.Close