(VBScript) Sign XML (XAdES) in the Cloud using Azure Key Vault

See more Signing in the Cloud Examples

Demonstrates how to sign XML using Azure Key Vault. The signing of the hash happens in the Cloud on Azure Key Vault. Everything else involving the updating the XML to add the signature happens locally within Chilkat.

Note: This example requires Chilkat v9.5.0.96 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Create the XML to be signed.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXml = CreateObject("Chilkat.StringBuilder")

bCrlf = 1
success = sbXml.AppendLine("<?xml version=""1.0"" encoding=""UTF-8"" standalone=""no"" ?>",bCrlf)
success = sbXml.AppendLine("<SOAP-ENV:Envelope xmlns:SOAP-ENV=""http://schemas.xmlsoap.org/soap/envelope/"">",bCrlf)
success = sbXml.AppendLine("    <SOAP-ENV:Header>",bCrlf)
success = sbXml.AppendLine("        <wsse:Security xmlns:wsse=""http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd"" SOAP-ENV:mustUnderstand=""1""></wsse:Security>",bCrlf)
success = sbXml.AppendLine("    </SOAP-ENV:Header>",bCrlf)
success = sbXml.AppendLine("    <SOAP-ENV:Body xmlns:SOAP-SEC=""http://schemas.xmlsoap.org/soap/security/2000-12"" SOAP-SEC:id=""Body"">",bCrlf)
success = sbXml.AppendLine("        <z:FooBar xmlns:z=""http://example.com"" />",bCrlf)
success = sbXml.AppendLine("    </SOAP-ENV:Body>",bCrlf)
success = sbXml.AppendLine("</SOAP-ENV:Envelope>",bCrlf)

' Load the certificate used for signing.  The certificate's private key is stored in 
' the Azure Key Vault.
' However, we still need the certificate locally (without private key).
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromFile("qa_data/certs/myCert.cer")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Here's a screenshot of our certificate with private key on Azure Key Vault:


' To sign using the Azure Key Vault, 
' add the following lines of code to specify your authentication credentials,
' and the name of the certificate w/ private key on the Azure server to be used.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonAzure = CreateObject("Chilkat.JsonObject")
' Set the "service" equal to "azure_keyvault" to tell Chilkat to use Azure Key Vault for signing.
success = jsonAzure.UpdateString("service","azure_keyvault")
success = jsonAzure.UpdateString("client_id","APP_ID")
success = jsonAzure.UpdateString("client_secret","APP_PASSWORD")
success = jsonAzure.UpdateString("tenant_id","TENANT_ID")
' In the above screenshot, our vault name is "kvchilkat".  You will use your vault name.
success = jsonAzure.UpdateString("vault_name","VAULT_NAME")
' In the above screenshot, our cert name is "ChilkatTest1".  You will use your cert name.
success = jsonAzure.UpdateString("cert_name","CERT_NAME")
' In the above screenshot, our cert version is "63b94a23389546ecbc8eb6208a1bef37".  You will use your cert version.
success = jsonAzure.UpdateString("cert_version","CERT_VERSION")
success = cert.SetCloudSigner(jsonAzure)

' Prepare for signing...
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSigGen")
set gen = CreateObject("Chilkat.XmlDSigGen")

' Indicate where the Signature will be inserted.
gen.SigLocation = "SOAP-ENV:Envelope|SOAP-ENV:Header|wsse:Security"

' Add a reference to the fragment of the XML to be signed.

' Note: "Body" refers to the XML element having an "id" equal to "Body", where "id" is case insensitive
' and where any namespace might qualify the attribute.  In this case, the SOAP-ENV:Body fragment is signed
' NOT because the tag = "Body", but because it has SOAP-SEC:id="Body"
success = gen.AddSameDocRef("Body","sha1","EXCL_C14N","","")

' (You can read about the SignedInfoPrefixList in the online reference documentation.  It's optional..)
gen.SignedInfoPrefixList = "wsse SOAP-ENV"

gen.KeyInfoType = "X509Data"
gen.X509Type = "IssuerSerial"

bUsePrivateKey = 1
success = gen.SetX509Cert(cert,bUsePrivateKey)
If (success <> 1) Then
    outFile.WriteLine(gen.LastErrorText)

    WScript.Quit
End If

' Everything's specified.  Now create and insert the Signature
' (The actual signing of the hash will happen on the Aruba server.)
success = gen.CreateXmlDSigSb(sbXml)
If (success <> 1) Then
    outFile.WriteLine(gen.LastErrorText)
    WScript.Quit
End If

' Examine the XML with the digital signature inserted
outFile.WriteLine(sbXml.GetAsString())

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

outFile.Close