(VBScript) Azure Storage: Get Blob Service Stats

Azure Storage Blob Service REST API: Sample code to get Blob Service Stats

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Get Blob Service Stats

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
' ---- IMPORTANT ----
' The "-secondary" suffix is required.
' This requires an Azure storage account with replication set to "Read-access geo-redundant storage (RA-GRS)"
' If you made the change just prior to testing this example, you'll need to give it time for the 
' DNS to become available..  
' ---- IMPORTANT ----
success = rest.Connect("chilkat-secondary.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

responseStr = rest.FullRequestNoBody("GET","/?restype=service&comp=stats")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' Load the XML response for parsing.
' An example of the response XML is shown below.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseStr)

outFile.WriteLine(xml.GetXml())

' Use the ChilkatPath method to get various pieces of information out
' of the XML.  For example:

outFile.WriteLine("Status = " & xml.ChilkatPath("GeoReplication|Status|*"))
lastSyncTimeStr = xml.ChilkatPath("GeoReplication|LastSyncTime|*")
outFile.WriteLine("LastSyncTime = " & lastSyncTimeStr)

' The date/time string can be loaded into a CkDateTime object for 
' access to individual parts, or conversion to other formats.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dateTime = CreateObject("Chilkat.CkDateTime")
success = dateTime.SetFromRfc822(lastSyncTimeStr)

' For example:
bLocalTime = 1
' dt is a Chilkat.DtObj
Set dt = dateTime.GetDtObj(bLocalTime)
outFile.WriteLine(dt.Year & "/" & dt.Month & "/" & dt.Day)

' <StorageServiceStats>
'     <GeoReplication>
'         <Status>live</Status>
'         <LastSyncTime>Tue, 03 May 2016 23:57:54 GMT</LastSyncTime>
'     </GeoReplication>
' </StorageServiceStats>

outFile.Close