(VBScript) Azure Storage: Get Blob Service Properties

Azure Storage Blob Service REST API: Sample code to get a blob's service properties.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure Blob Service Example: Get Blob Service Properties

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

responseStr = rest.FullRequestNoBody("GET","/?restype=service&comp=properties")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' Load the XML response for parsing.
' An example of the response XML is shown below.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseStr)

outFile.WriteLine(xml.GetXml())

' Use the ChilkatPath method to get various pieces of information out
' of the XML.  For example:

outFile.WriteLine("Logging retention policy #days = " & xml.ChilkatPath("Logging|RetentionPolicy|Days|*"))
outFile.WriteLine("Hour metrics include APIs = " & xml.ChilkatPath("HourMetrics|IncludeAPIs|*"))

' <?xml version="1.0" encoding="utf-8" ?>
' <StorageServiceProperties>
'     <Logging>
'         <Version>1.0</Version>
'         <Read>true</Read>
'         <Write>true</Write>
'         <Delete>true</Delete>
'         <RetentionPolicy>
'             <Enabled>true</Enabled>
'             <Days>7</Days>
'         </RetentionPolicy>
'     </Logging>
'     <HourMetrics>
'         <Version>1.0</Version>
'         <Enabled>true</Enabled>
'         <IncludeAPIs>true</IncludeAPIs>
'         <RetentionPolicy>
'             <Enabled>true</Enabled>
'             <Days>7</Days>
'         </RetentionPolicy>
'     </HourMetrics>
'     <MinuteMetrics>
'         <Version>1.0</Version>
'         <Enabled>false</Enabled>
'         <RetentionPolicy>
'             <Enabled>false</Enabled>
'         </RetentionPolicy>
'     </MinuteMetrics>
'     <Cors />
' </StorageServiceProperties>

outFile.Close