(VBScript) Azure File Service: Upload File

Sample code to upload a file to a directory in a share in the Azure File Service. A file is uploaded by first creating the file in the Azure share and then writes a range of bytes to the file. Azure imposes a 4MB limit for each PUT to write a range. Files larger than 4MB need to be uploaded by making multiple "Put Range" calls. This example uploads a file small enough for a single "Put Range" call.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Azure File Service Example: Upload a file.  
' See:  https://docs.microsoft.com/en-us/rest/api/storageservices/create-share
' also see: https://docs.microsoft.com/en-us/rest/api/storageservices/put-range

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.file.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' This example will upload a relatively small file (760K), so it may as well 
' just be load it into memory..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set jpgData = CreateObject("Chilkat.BinData")
success = jpgData.LoadFile("qa_data/jpg/penguins.jpg")

' Provide Azure Cloud credentials for the REST calls.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAzureStorage")
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "File"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' However, a few additional headers are required for the "Create File" operation:
success = rest.AddHeader("x-ms-type","file")

' This required header specifies the final size of the file (or the maximum size it can be).
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbFileSize = CreateObject("Chilkat.StringBuilder")
success = sbFileSize.AppendInt(jpgData.NumBytes)
success = rest.AddHeader("x-ms-content-length",sbFileSize.GetAsString())

' Send a PUT request to create the file (or replace the file if it already exists).
' This will initialize the file in the Azure file storage.  To upload content, we'll need
' to do the "Put Range" operation one or more times.

' The following will create the file "penguins.jpg" in the share "pip", in the directory "/wildlife/antarctic"
responseStr = rest.FullRequestNoBody("PUT","/pip/wildlife/antarctic/penguins.jpg")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure File Service will respond with a 201 (Created) response status code,
' with no XML response body.  If an error response is returned, there will be an XML response body.

If (rest.ResponseStatusCode <> 201) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Successfully created penguins.jpg")

' --------------------------------------------------------------------------------
' Upload the file data...

' Make sure the headers from the "Create File" operation are removed.
success = rest.ClearAllHeaders()

' The only tricky part here is to correctly add the x-ms-range header.
' It will be formatted like this:
' x-ms-range: bytes=0-759623

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbRange = CreateObject("Chilkat.StringBuilder")
success = sbRange.Append("bytes=0-")
success = sbRange.AppendInt(jpgData.NumBytes - 1)

success = rest.AddHeader("x-ms-range",sbRange.GetAsString())

' The x-ms-write header is also required:
success = rest.AddHeader("x-ms-write","update")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponseBody = CreateObject("Chilkat.StringBuilder")
' IMPORTANT:  Don't forget the "?comp=range" at the end of the path passed in the 2nd argument.
success = rest.FullRequestBd("PUT","/pip/wildlife/antarctic/penguins.jpg?comp=range",jpgData,sbResponseBody)
If (success <> 1) Then
    ' This would indicate a failure where no response was received.
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A 201 response indicates the data was uploaded.
If (rest.ResponseStatusCode <> 201) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Successfully uploaded data into penguins.jpg")

outFile.Close