VBScript

Azure File Service: List Shares

See more Azure Cloud Storage Examples

Sample code to list the file shares in an Azure storage account. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Azure File Service Example: List all the file shares in a storage account.
' See also: https://docs.microsoft.com/en-us/rest/api/storageservices/list-shares

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.file.core.windows.net",port,bTls,bAutoReconnect)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "File"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' Send the GET request to list the shares.
responseStr = rest.FullRequestNoBody("GET","/?comp=list")
If (rest.LastMethodSuccess = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 200 response status code,
' with an XML response body.

If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

' Load the XML response for parsing.
' An example of the response XML is shown below.
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseStr)

outFile.WriteLine(xml.GetXml())

' Here's a sample response:

' <?xml version="1.0" encoding="utf-8" ?>
' <EnumerationResults ServiceEndpoint="https://chilkat.file.core.windows.net/">
'     <Shares>
'         <Share>
'             <Name>beardie</Name>
'             <Properties>
'                 <Last-Modified>Mon, 26 Jun 2017 21:24:57 GMT</Last-Modified>
'                 <Etag>"0x8D4BCD9CBD872E5"</Etag>
'                 <Quota>5120</Quota>
'             </Properties>
'         </Share>
'         <Share>
'             <Name>pip</Name>
'             <Properties>
'                 <Last-Modified>Mon, 26 Jun 2017 21:24:44 GMT</Last-Modified>
'                 <Etag>"0x8D4BCD9C3D823D1"</Etag>
'                 <Quota>5120</Quota>
'             </Properties>
'         </Share>
'     </Shares>
'     <NextMarker />
' </EnumerationResults>

' Let's iterate over the file shares
set lastMod = CreateObject("Chilkat.CkDateTime")

numShares = xml.NumChildrenAt("Shares")
i = 0
set dt = CreateObject("Chilkat.DtObj")
Do While i < numShares
    outFile.WriteLine("---- Share " & i & " ----")
    xml.I = i
    outFile.WriteLine("Name: " & xml.GetChildContent("Shares|Share[i]|Name"))
    success = lastMod.SetFromRfc822(xml.GetChildContent("Shares|Share[i]|Properties|Last-Modified"))
    lastMod.ToDtObj 1,dt

    outFile.WriteLine("Last-Modified YMD: " & dt.Year & "," & dt.Month & "," & dt.Day)
    i = i + 1
Loop

' Output for the above loop:

' ---- Share 0 ----
' Name: beardie
' Last-Modified YMD: 2017,6,26
' ---- Share 1 ----
' Name: pip
' Last-Modified YMD: 2017,6,26
' 

outFile.WriteLine("Success.")

outFile.Close