VBScript

Azure Storage: Delete Container

See more Azure Cloud Storage Examples

Azure Storage Blob Service REST API: Sample code to mark a container for deletion. The container and any blobs contained within it are later deleted during garbage collection. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Azure Blob Service Example: Delete Container
' See also: https://msdn.microsoft.com/en-us/library/azure/dd179408.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

' To call Delete Container on a container that has an active lease, specify the lease ID in this header. 
' If this header is not specified when there is an active lease, Delete Container will return 409 (Conflict). 
' If you specify the wrong lease ID, or a lease ID on a container that does not have an active lease, 
' Delete Container will return 412 (Precondition failed).

' IMPORTANT: Delete this line, or insert a valid lease ID, otherwise the request
' will fail with a 400 status code..
success = rest.AddHeader("x-ms-lease-id","SOME_LEASE_ID")

' The expected success response is a 202 response status code with no response body.
' In this example, the container to be deleted is named "mycontainer".
responseStr = rest.FullRequestNoBody("DELETE","/mycontainer?restype=container")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the Azure Storage service will respond with a 202 response code,
' with no response body.

' If the container with the same name already exists, then the operation will fail.
If (rest.ResponseStatusCode <> 202) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine("Success: Container marked for deletion.")

outFile.Close